proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 67 insertions, 0 deletions

diff --git a/games-puzzle/jag/jag-0.3.2.ebuild b/games-puzzle/jag/jag-0.3.2.ebuild
new file mode 100644
index 000000000000..e48f2cfd296e
--- /dev/null
+++ b/games-puzzle/jag/jag-0.3.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils qt4-r2 games
+
+DESCRIPTION="Arcade 2D Puzzle Game"
+HOMEPAGE="http://jag.xlabsoft.com/"
+SRC_URI="http://jag.xlabsoft.com/files/${P}-src.zip
+	http://jag.xlabsoft.com/files/${P}-data.zip"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+IUSE="editor"
+
+RDEPEND="dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	dev-qt/qtopengl:4
+	x11-libs/libXrandr
+	media-libs/libsdl[sound,video]
+	media-libs/sdl-mixer"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${P}-src
+
+src_prepare() {
+	mv "${WORKDIR}"/${P}-data/data "${WORKDIR}"/${P}-src/
+	sed -i \
+		-e "s:/usr/local/bin:${GAMES_BINDIR}:g" \
+		-e "s:/usr/local/games:${GAMES_DATADIR}:g" \
+		-e "s:LIBS += -lSDLmain:LIBS += -lSDL -lX11:" \
+		Game.pro main.cpp editor/editor.pro \
+		|| die "sed failed"
+}
+
+src_configure() {
+	qt4-r2_src_configure
+	if use editor; then
+		cd editor
+		eqmake4 editor.pro
+	fi
+}
+
+src_compile() {
+	qt4-r2_src_compile
+	if use editor; then
+		cd editor
+		qt4-r2_src_compile
+	fi
+}
+
+src_install() {
+	qt4-r2_src_install
+	newicon images/logo.png ${PN}.png
+	make_desktop_entry jag Jag
+
+	if use editor; then
+		cd editor
+		qt4-r2_src_install
+		make_desktop_entry jag-editor "Jag Level editor" ${PN}
+	fi
+
+	prepgamesdirs
+}