games-rpg/pcgen: add 6.06.01

Technically 6.08.00_rc8 is the current stable per upstream website
(despite _rc8 as it appears final with development shifted to 6.10),
but requires masked virtual/jre-11. Adding previous stable meanwhile.

Could use more work and building from source, but that needs Gradle.
Moved files to /opt from /usr/share due to being prebuilt.

Closes: https://bugs.gentoo.org/611908
Closes: https://bugs.gentoo.org/672972
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 37 insertions, 0 deletions

diff --git a/games-rpg/pcgen/pcgen-6.06.01.ebuild b/games-rpg/pcgen/pcgen-6.06.01.ebuild
new file mode 100644
index 000000000000..6bf03db1d130
--- /dev/null
+++ b/games-rpg/pcgen/pcgen-6.06.01.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop edos2unix
+
+DESCRIPTION="D&D character generator"
+HOMEPAGE="http://pcgen.org/"
+SRC_URI="https://github.com/PCGen/pcgen/releases/download/${PV}/${P}-full.zip"
+S="${WORKDIR}/${PN}"
+
+LICENSE="LGPL-2.1 OGL-1.0a"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=virtual/jre-1.8:*"
+BDEPEND="app-arch/unzip"
+
+src_prepare() {
+	default
+
+	edos2unix ${PN}.sh
+	sed "/^cd /c\\cd \"${EPREFIX}/opt/${PN}\" || exit 1" ${PN}.sh > "${T}"/${PN} || die
+
+	rm -r LICENSE docs/{doc_tools,pngcrush_logs.txt} ${PN}.{exe,sh} || die
+}
+
+src_install() {
+	dobin "${T}"/${PN}
+
+	insinto /opt/${PN}
+	doins -r .
+
+	newicon system/sponsors/pcgen/pcgen_128x128.png ${PN}.png
+	make_desktop_entry ${PN} PCGen
+}