gnome-extra/gnome-shell-extension-gsconnect: add 56_pre20231004

Closes: https://bugs.gentoo.org/743805
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/Manifest b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
index 5081531f5add..584a15ff3a5b 100644
--- a/gnome-extra/gnome-shell-extension-gsconnect/Manifest
+++ b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
@@ -1 +1,2 @@
 DIST gnome-shell-extension-gsconnect-55.tar.gz 908942 BLAKE2B 760d73ead4a76af5a1292202ba61b3b72b95551a8ece3b830d7ff4a9803a2267c1d00b79a56dc22df4d9ffb8247956a0a25e720c00e2938e0e5f5ed8b5a2e56e SHA512 152ad0a118ef10840b8b08e00d92e697feb600d473a3d0db48dccba113906bdd49e1af75276554a0782057ef80cdda7aca768b54e0c75c3a5fc249706492e938
+DIST gnome-shell-extension-gsconnect-56_pre20231004.tar.gz 878213 BLAKE2B c0dfa7f2a30b8281b2bdc244f801221e644de6ae0d71f9eda6366a4701f53111da0621b000352642c22c2bf9618b966751e94de3c9765da4efff9463e8e4fd20 SHA512 4ff5df44c3d729d5c37ad585caf5e9e6f3d98f5d1bdeed3c10471ac4bc60242a56a87ea5da0a54e6ee827e48d8a26f9f75138f5824d984803d5a93bde9611b37
diff --git a/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-56_pre20231004.ebuild b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-56_pre20231004.ebuild
new file mode 100644
index 000000000000..eda14cff6d1d
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-56_pre20231004.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2-utils meson readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/GSConnect/gnome-shell-extension-gsconnect"
+#SRC_URI="https://github.com/GSConnect/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+COMMIT="018c7fe6172231eb27b7dc2f640eccd229c7319c"
+SRC_URI="https://github.com/GSConnect/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nautilus"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.68
+	=gnome-base/gnome-shell-45*
+	gnome-base/gvfs
+	gnome-extra/evolution-data-server
+	|| ( media-libs/libcanberra media-libs/gsound )
+	nautilus? (
+		dev-python/nautilus-python
+		gnome-base/nautilus[introspection] )
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_configure() {
+	# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
+	# https://bugs.gentoo.org/694388
+	meson_src_configure \
+		-Dinstalled_tests=false \
+		-Dnemo=false \
+		$(meson_use nautilus)
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}