proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 54 insertions, 0 deletions

diff --git a/gnustep-base/gnustep-gui/gnustep-gui-0.24.0.ebuild b/gnustep-base/gnustep-gui/gnustep-gui-0.24.0.ebuild
new file mode 100644
index 000000000000..7f99276889ca
--- /dev/null
+++ b/gnustep-base/gnustep-gui/gnustep-gui-0.24.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit gnustep-base multilib
+
+DESCRIPTION="Library of GUI classes written in Obj-C"
+HOMEPAGE="http://www.gnustep.org/"
+SRC_URI="ftp://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha amd64 ppc sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="cups gif jpeg png speech"
+
+DEPEND="${GNUSTEP_CORE_DEPEND}
+	app-text/aspell
+	>=gnustep-base/gnustep-base-1.24.6
+	media-libs/audiofile
+	>=media-libs/tiff-3
+	x11-libs/libXt
+	cups? ( >=net-print/cups-1.7.4 )
+	gif? ( >=media-libs/giflib-4.1 )
+	jpeg? ( virtual/jpeg )
+	png? ( >=media-libs/libpng-1.2 )
+	speech? ( app-accessibility/flite )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	gnustep-base_src_prepare
+
+	# remove hardcoded -g -Werror, bug #378179
+	sed -i -e 's/-g -Werror//' \
+		Tools/say/GNUmakefile \
+		Tools/speech/GNUmakefile \
+		|| die
+}
+
+src_configure() {
+	egnustep_env
+
+	local myconf=
+	use gif && myconf="--disable-ungif --enable-libgif"
+
+	econf \
+		$(use_enable cups) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable speech) \
+		--with-tiff-include="${EPREFIX}"/usr/include \
+		--with-tiff-library="${EPREFIX}"/usr/$(get_libdir) \
+		${myconf}
+}