kde-apps/cantor: 20.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 110 insertions, 0 deletions

diff --git a/kde-apps/cantor/Manifest b/kde-apps/cantor/Manifest
index 75ecdd7f3cb6..cff52536bf65 100644
--- a/kde-apps/cantor/Manifest
+++ b/kde-apps/cantor/Manifest
@@ -1 +1,2 @@
 DIST cantor-20.04.3.tar.xz 9029068 BLAKE2B c5b436304d3aa84150a0994d556318600f73ccb606b59fc67d8476828c356f54d64cda85f781c9c939403b0bb6808e2a943d37ad306fbc751800944ad27e74f4 SHA512 07351d8b4b72653394a337bc3ae5c8f8c669dd8cd66f4cf9d41bbdd25b47a8b3666f79580e319ef56c878ab626ce959d825b4a34243c5f639de96674a1bc111d
+DIST cantor-20.08.0.tar.xz 9078720 BLAKE2B e630d3d6fbd24b67927dcc7b4480e6e454dff00a8bcbe9ed5d42211b6f91bc826e8be4d4c2f02ec517aea0d61500b438c79b2994fe24431eb8fdc6bf9b75af5d SHA512 2b73804e30541a22f5eb1f74d82d44918c7340477219392094849fd0c9530b3ca227a46ed2a75b61ce01bb52eb95f4852c9340101c199bdad040efe74988b578
diff --git a/kde-apps/cantor/cantor-20.08.0.ebuild b/kde-apps/cantor/cantor-20.08.0.ebuild
new file mode 100644
index 000000000000..7843f905d12a
--- /dev/null
+++ b/kde-apps/cantor/cantor-20.08.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{7,8} )
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Interface for doing mathematics and scientific computing"
+HOMEPAGE="https://kde.org/applications/education/org.kde.cantor
+https://edu.kde.org/cantor/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+analitza julia lua postscript python qalculate R"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-qt/qtxmlpatterns-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	analitza? ( >=kde-apps/analitza-${PVCUT}:5 )
+	julia? ( dev-lang/julia )
+	lua? ( dev-lang/luajit:2 )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate:=
+	)
+	postscript? ( app-text/libspectre )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-qt/qtdbus-${QTMIN}:5
+	)
+	R? ( dev-lang/R )
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT+=" test"
+
+pkg_pretend() {
+	ecm_pkg_pretend
+
+	if ! has_version sci-mathematics/maxima && ! has_version sci-mathematics/octave && \
+		! use analitza && ! use julia && ! use lua && ! use python && ! use qalculate && ! use R; then
+		elog "You have decided to build ${PN} with no backend."
+		elog "To have this application functional, please enable one of the backends via USE flag:"
+		elog "    analitza, lua, python, qalculate, R"
+		elog "Alternatively, install one of these:"
+		elog "    # emerge sci-mathematics/maxima (bug #619534)"
+		elog "    # emerge sci-mathematics/octave"
+		elog "Experimental available USE flag:"
+		elog "    julia (not stable, bug #613576)"
+		elog
+	fi
+
+	if ! has_version virtual/latex-base; then
+		elog "For LaTeX support:"
+		elog "    # emerge virtual/latex-base"
+	fi
+}
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	use julia && addpredict /proc/self/mem # bug 602894
+
+	local mycmakeargs=(
+		$(cmake_use_find_package analitza Analitza5)
+		$(cmake_use_find_package julia Julia)
+		$(cmake_use_find_package lua LuaJIT)
+		-DUSE_LIBSPECTRE=$(usex postscript)
+		$(cmake_use_find_package python PythonLibs3)
+		$(cmake_use_find_package qalculate Qalculate)
+		$(cmake_use_find_package R R)
+	)
+	ecm_src_configure
+}