kde-apps/gwenview: 20.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/kde-apps/gwenview/Manifest b/kde-apps/gwenview/Manifest
index fa49857f0ed1..d82bcf6bf767 100644
--- a/kde-apps/gwenview/Manifest
+++ b/kde-apps/gwenview/Manifest
@@ -1 +1,2 @@
 DIST gwenview-20.04.3.tar.xz 5629044 BLAKE2B 3895b5a4b3a858784470a0d72e473c651047f9b6f808b89192556d12fd80d798703d33a3409f3fbc2b35771b1ad1dc5f840f4935ca25c4f66b7130dd3a2bbf45 SHA512 c670111e75938028713ea77695bbe6fdd8e76d0dea74acc0cff3a20dd5a7ee4c956ef79b67c7ac8e99bb07b9895c16fcf985580d91442005451c6439f19726f1
+DIST gwenview-20.08.0.tar.xz 6740312 BLAKE2B ae268eb69c4e914dca1c4f00d74ae1e47f03ea73f47b231e697ec0f58143a65609201c14d102a35a30a5b159b0388418846addd6e3f535e8eace4dde0ea9863c SHA512 ba811b8e3b3144b69823f3da7d6b7dbf0916e309cc39fa2b40a7ce5163b34bc976f67af45a078c2480b7f7eea9ae1daa058d792912992ec043bc75262e8f94fa
diff --git a/kde-apps/gwenview/gwenview-20.08.0.ebuild b/kde-apps/gwenview/gwenview-20.08.0.ebuild
new file mode 100644
index 000000000000..2c0641248edd
--- /dev/null
+++ b/kde-apps/gwenview/gwenview-20.08.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Image viewer by KDE"
+HOMEPAGE="https://kde.org/applications/graphics/org.kde.gwenview
+https://userbase.kde.org/Gwenview"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="activities fits kipi +mpris raw semantic-desktop share X"
+
+# requires running environment
+RESTRICT+=" test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtopengl-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-gfx/exiv2:=
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	media-libs/phonon[qt5(+)]
+	media-libs/tiff
+	virtual/jpeg:0
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	fits? ( sci-libs/cfitsio )
+	kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
+	mpris? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	raw? ( >=kde-apps/libkdcraw-${PVCUT}:5 )
+	semantic-desktop? (
+		>=kde-frameworks/baloo-${KFMIN}:5
+		>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	)
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtimageformats-${QTMIN}:5
+	>=kde-frameworks/kimageformats-${KFMIN}:5
+	kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use mpris; then
+		# FIXME: upstream a better solution
+		sed -e "/set(HAVE_QTDBUS/s/\${Qt5DBus_FOUND}/0/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package fits CFitsio)
+		$(cmake_use_find_package kipi KF5Kipi)
+		$(cmake_use_find_package raw KF5KDcraw)
+		$(cmake_use_find_package share KF5Purpose)
+		$(cmake_use_find_package X X11)
+	)
+
+	if use semantic-desktop; then
+		mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=Baloo )
+	else
+		mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=None )
+	fi
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version kde-apps/svgpart:${SLOT} ; then
+		elog "For SVG support, install kde-apps/svgpart:${SLOT}"
+	fi
+}