kde-apps/k3b: 20.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 122 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index 6633055df347..8695ebe422b0 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,2 +1,3 @@
 DIST k3b-20.04.3.tar.xz 10509884 BLAKE2B 9bc05efbc06e9909e36fd23e56aef95182f3db9a82b2ca9c5404b5fa839eb71a411a92492591ff7b5d0875a296d71ee02a4008c61051da6b893628801f096a48 SHA512 ba45206ba25df77356b1afefe3b601cebc26610d87068af5c3d4939b407de8f08890ca7ed8b0e0059f0bd98adc9786b00bec3f0ec142488b686d0663c3cc65b2
 DIST k3b-20.08.1.tar.xz 10681496 BLAKE2B f4692418f8085ab4b76d3defc8ed5e1e3f888ac4f4606523d9fa7d5c63085e095d1ce92fedeb0b797dac3260fd328b0a4998b09c63fbdc9a2709234539f95059 SHA512 b0d6e6e5372916963a0e6c405792c55c4bb70e56564aaad65e7c2e79177d651f9edc84d6813900b18acaf657429909453a5ac1b47f4624c1751ecc56ded52b93
+DIST k3b-20.08.2.tar.xz 10681572 BLAKE2B 1f52724a307091bf81eb85906cfb1f4f4313b026862ab2f65226ed699460da452261423f76d6f545cf55bc31d9f47468f359a9e1c9ce4fffe34fe0eb9da45580 SHA512 ca35a414ab747f5e8ce99fd58ef4376dbc8be8760d9e92527745de722a0ee0418eb5ce1098edfb611b30c75781d36c77a14c47a73f27ca1d43a58652679b8565
diff --git a/kde-apps/k3b/k3b-20.08.2.ebuild b/kde-apps/k3b/k3b-20.08.2.ebuild
new file mode 100644
index 000000000000..7807ff5baa31
--- /dev/null
+++ b/kde-apps/k3b/k3b-20.08.2.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://kde.org/applications/multimedia/org.kde.k3b
+https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dvd encode ffmpeg flac mad mp3 musepack sndfile sox taglib vcd vorbis"
+
+REQUIRED_USE="
+	flac? ( taglib )
+	mp3? ( encode taglib )
+	sox? ( encode taglib )
+"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-apps/libkcddb-${PVCUT}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib?]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	dev-libs/libburn
+	media-sound/cdparanoia
+	virtual/cdrtools
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}