kde-apps/kwave: 20.12.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index ffdc16a80296..7a2ddb300bbd 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-20.08.3.tar.xz 6878552 BLAKE2B 1708bc448399b7fd71be9cd21ae949efdfc1f3d871fcfabd4330150ed91faa65acf5dda50c81c2a0d275dd252e324af09c051d8be6873f1cdb21428ba4d33206 SHA512 63829dc2b39e8c78168f7c436dbc60334fccb92ba5c18b37f3e91b117ef9c3c53cb4957862362841986f25cf6cae210cdb9e2dba74d8c9ac486756ef675d98c4
 DIST kwave-20.12.0.tar.xz 6881696 BLAKE2B 33606d8a04acac4db73082482a3584fc9ae616b51b82445c240878b07ba6b5de791414e40e5eeaab832c7a9f4cef74ebe405adaa3defc42e43b5c2a5261f1911 SHA512 f50778204113d1bd2cb0ed484d661d495c4de832a77d8006da8a73fdb5d131d294fc293637c57b81aa98cc3759f72336aae7bbd5e0dcdf51a2eee5ea715bace8
+DIST kwave-20.12.1.tar.xz 6881684 BLAKE2B 23e539bdb477646a07e907ffe40e7bf01df37ff9ce85e24b50ca643c471525c4f3167183cc31e56281d9922eb64d6078e32c28b0da7e0ec86105b0b317d41f19 SHA512 4a9ca690c3000c76150fba20e3f777a96ce65fefb2be03778b477dd3ab96b8702e77eef2ff6fcd01b4d5b388f2f1ec8f21ac47d78690b315add276154aaacc26
diff --git a/kde-apps/kwave/kwave-20.12.1.ebuild b/kde-apps/kwave/kwave-20.12.1.ebuild
new file mode 100644
index 000000000000..023e2e265ec6
--- /dev/null
+++ b/kde-apps/kwave/kwave-20.12.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.75.0
+QTMIN=5.15.1
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/en/kwave"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}