kde-apps: Add KDE Applications 19.08.3

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/kde-apps/libkcddb/libkcddb-19.08.3.ebuild b/kde-apps/libkcddb/libkcddb-19.08.3.ebuild
new file mode 100644
index 000000000000..da374aa6143a
--- /dev/null
+++ b/kde-apps/libkcddb/libkcddb-19.08.3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.60.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE library for CDDB"
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="musicbrainz"
+
+DEPEND="
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	musicbrainz? ( media-libs/musicbrainz:5 )
+"
+RDEPEND="${DEPEND}"
+
+# tests require network access and compare static data with online data
+# bug 280996
+RESTRICT+=" test"
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use handbook ; then
+		pushd kcmcddb > /dev/null
+		cmake_comment_add_subdirectory doc
+		popd > /dev/null
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package musicbrainz MusicBrainz5)
+	)
+
+	ecm_src_configure
+}