kde-frameworks/breeze-icons: 5.94.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 57 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index abb905f7e6c6..1a4bcc2bb926 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1,2 +1,3 @@
 DIST breeze-icons-5.92.0.tar.xz 2147592 BLAKE2B a4b8bb0d05c38c90d2c8170918b1ad9abe0100bf1323f8b5089d43e698d117e2959cce6d7cc39f634c8e008fdde5ae8a2acdb830356df4b07f601e9ec2ba4ebc SHA512 830309765695df290e249d6aff6685867e8a394e5a39e0df66b2566cb3d8bf5eb973a33fc61f69bf410b16ea5644f967da557a7c3d1cc349eb1fc429d997597b
 DIST breeze-icons-5.93.0.tar.xz 2148300 BLAKE2B 6aa9101f7e803f90ed6aeee5d9d8d586bfb4b6a80fe1e4f15aaca7ce11318a281037aae21a37043793b8920f6291346230848ab216f07e10556326be116360c9 SHA512 7a011b0784acfe0c813e2f1f44a8e89c878af658db8a23e4c0c8da234cf88f7f8904adf2f17f24827b0f33c9919bc304a6ab91ee742422e59664f5db0c657ba0
+DIST breeze-icons-5.94.0.tar.xz 2151008 BLAKE2B 1aa8826c57d894d01545f344dc7e01b2db7ff0f87938ca2ed10962760912e73e5f3747457c32c2e7f17cd5739cffd84f6f9d8a5d7ac4f6ff1ce2f1b78993e541 SHA512 63f58c75864b3791c7b7ab87666c49328589cd2867f166e496553281497375d9c6054c3ddfea7c6101092d8636d35d4c263fdccd3a58b50d9dd2a14210facb5c
diff --git a/kde-frameworks/breeze-icons/breeze-icons-5.94.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-5.94.0.ebuild
new file mode 100644
index 000000000000..152a388fe1ee
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-5.94.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake kde.org python-any-r1 xdg-utils
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}