kde-frameworks: Add KDE Frameworks 5.55.0

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
index 1851c838b870..71feac40fc9b 100644
--- a/kde-frameworks/kfilemetadata/Manifest
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -1 +1,2 @@
 DIST kfilemetadata-5.54.0.tar.xz 302204 BLAKE2B ecf9a4fac9fcf18fc5344fd29eb2e28bebc1e65762c9f62b1e07abf67e2a55bd677b16a02fafa2308a63757f0adcc35e4dac47244a05df067026c0da11553c40 SHA512 bfa8287e5c8df363908a441419d377d33ea2cd93a4fc69fc47c69da80ad0e3a80e60f26b4856c3d3e04128e6ac59b214ee0613e37dda29f2537f502789bd4801
+DIST kfilemetadata-5.55.0.tar.xz 302672 BLAKE2B 723a7db0086891b072cc9b393157e2ce66f3cc1bf6a7254832aede90e6dcbfeea3ade81ec229763a896ed3b463c4bc64bb766566cc88984a83ee378b9f43088b SHA512 18d5a17ba8f264c3f510c3d7a087e476181b829131d8774bdb3c4f4ef40b16c31c9b2ed26fc5a994c52959ae4a715f520743ee18cad94d2760aafdf6170414b8
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.55.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.55.0.ebuild
new file mode 100644
index 000000000000..0711a76b9a58
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.55.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+inherit kde5 python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux libav office pdf taglib"
+
+BDEPEND="
+	test? ( ${PYTHON_DEPS} )
+"
+RDEPEND="
+	$(add_frameworks_dep ki18n)
+	$(add_qt_dep qtxml)
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? (
+		libav? ( >=media-video/libav-12.2:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	office? ( $(add_frameworks_dep karchive) )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	kde5_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package epub EPub)
+		$(cmake-utils_use_find_package exif LibExiv2)
+		$(cmake-utils_use_find_package ffmpeg FFmpeg)
+		$(cmake-utils_use_find_package office KF5Archive)
+		$(cmake-utils_use_find_package pdf Poppler)
+		$(cmake-utils_use_find_package taglib Taglib)
+	)
+
+	kde5_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	kde5_src_test
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+		elog "To get additional features, optional runtime dependencies may be installed:"
+		elog "app-text/catdoc - indexing of Microsoft Word or Powerpoint files"
+		elog "dev-libs/libxls - indexing of Microsoft Excel files"
+	fi
+}