kde-plasma/plasma-nm: 5.19.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index ed5df8d88218..a9047e453d5d 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-nm-5.18.5.tar.xz 828008 BLAKE2B 557a31d5a0e7886be90e62be3f5328baf4a8bbfeb3e9decf1f2f106f33bef7e64fb886b94691faab57119f231b6bbcff58514d795df75f858ca9c8ea8c1af9a7 SHA512 8f785f257f274fb9384bf2afbe4231a057c46706483e26dd2270a93a6fc97e6198916ff119d258a67d4f8bb73facb0ff67412f43e5fa66812962edb64331db4a
 DIST plasma-nm-5.19.3.tar.xz 853800 BLAKE2B ef61bea29d86be937f77ec0a5ef0578ca1b16b6aad296c236471a7b0b6a96a78d6af4410545dab6798fdf9b6858d9beea83a63fccb73a8f354ad6cb262662edf SHA512 987eb49e2b18526631da063097afd5cf968dbd898078ad2eda27d085fc6e9b24252ae134ef529e5760db346d9c723910653e52033a5d4b0f17ebbc3883bd534d
+DIST plasma-nm-5.19.4.tar.xz 853896 BLAKE2B 82275f0a926fbff0e4d39b09bd463d8440a0f183b2a6cd9baacccddb703a2316968d5b59771970b77a28448b80b29e14aef77b395f03a8b5d3e35040fc62175f SHA512 e96c7457b243dcad51e4e4e246484c2241b7465d7f92a57f6bbb20ac7d6abb316d1a1b2d0ee8753060df15d15d6248ca7808610af911b450eea40f8c20ebc162
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.19.4.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.19.4.ebuild
new file mode 100644
index 000000000000..b3f6d5235a7f
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.19.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.71.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.1.1:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	net-misc/networkmanager[teamd=]
+	modemmanager? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+		net-misc/mobile-broadband-provider-info
+	)
+	openconnect? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.19.2-fix-inline-password-field.patch # KDE-bug #423093
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+		$(cmake_use_find_package modemmanager KF5ModemManagerQt)
+		$(cmake_use_find_package openconnect OpenConnect)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}