proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/lxde-base/lxsession/lxsession-0.4.9.2-r3.ebuild b/lxde-base/lxsession/lxsession-0.4.9.2-r3.ebuild
new file mode 100644
index 000000000000..27270a0ad8d4
--- /dev/null
+++ b/lxde-base/lxsession/lxsession-0.4.9.2-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+VALA_MIN_API_VERSION="0.14"
+VALA_MAX_API_VERSION="0.22"
+
+inherit vala autotools eutils
+
+DESCRIPTION="LXDE session manager (lite version)"
+HOMEPAGE="http://lxde.sf.net/"
+SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha amd64 arm ppc x86 ~arm-linux ~x86-linux"
+SLOT="0"
+# upower USE flag is enabled by default in the desktop profile
+IUSE="nls upower"
+
+COMMON_DEPEND="dev-libs/glib:2
+	dev-libs/libgee:0
+	dev-libs/dbus-glib
+	lxde-base/lxde-common
+	sys-auth/polkit
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	sys-apps/dbus"
+RDEPEND="${COMMON_DEPEND}
+	!lxde-base/lxsession-edit
+	sys-apps/lsb-release
+	upower? ( || ( sys-power/upower sys-power/upower-pm-utils ) )"
+DEPEND="${COMMON_DEPEND}
+	$(vala_depend)
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xproto"
+
+DOCS="AUTHORS ChangeLog README"
+
+src_prepare() {
+	# bug #488082
+	epatch "${FILESDIR}"/${P}-makefile.patch
+
+	# bug #497100
+	epatch "${FILESDIR}"/${P}-configure.patch
+
+	# bug #496880
+	epatch "${FILESDIR}"/${P}-fix-logind-dbus-calls.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	# dbus is used for restart/shutdown (CK, logind?), and suspend/hibernate (UPower)
+	econf \
+		$(use_enable nls)
+}