media-gfx/imagemagick: add 7.1.1.25

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 253 insertions, 0 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index cf05590b2b8c..8d687c068b97 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -3,3 +3,4 @@ DIST ImageMagick-6.9.13-2.tar.xz 9611768 BLAKE2B 0b0bb7dec536b12f0f5dc83b03b33a1
 DIST ImageMagick-6.9.13-3.tar.xz 9616088 BLAKE2B 9682bc15c42199c266cc8d9152099a96a4e66154b9c74cd7c72993c3d9edd8aa6123d64ae6852d520c9a346a27ee27120a4d2b4f7973c279006d7570666c4080 SHA512 3e061c8a7bec0c49db9e990858257ff092500430d382bcad0c76aaa8d531bd2c13b727a52f060fc6051a0217f41f254570d23a4301c15a7af547e13f148a4ca9
 DIST ImageMagick-7.1.1-11.tar.xz 10196156 BLAKE2B 328ffe6dbf30b597ec56f94ab5e74cca553cb47eca244c76b91273c278c097990fb8ed7eeaa22311d4408022808e752cbb4c8775c56b3d64d3a4216487093e9e SHA512 b3c839457b62a6b83d3ab9cf12bda2f41030eed75ae5ff898331ffdfe202a93ea8284c8f8608f4ecd013c7eb0c4cbef6527caff62bcf382d62e8531389628fc3
 DIST ImageMagick-7.1.1-24.tar.xz 10561928 BLAKE2B 992d1425a2e306f9bf85dfafb09f2869fae09b57a32c3b1992d4f478932ef6ec58368d70574f134e7226b09a6275cd1f4343064b36ca3fb8556a60d59138df2e SHA512 78dbd763f70b36e95a728cff7a1e02ec1c5d3b9a8371161e306e77450f1a3c33a987f19dda3eca94dfa2435b4a29a97c5df5155915a73441f74174a98b36a7d9
+DIST ImageMagick-7.1.1-25.tar.xz 10557080 BLAKE2B 833c450c87e4a1650b6d71e2d8abeea74ad6f0afa7ec6f0cba9c5bb39044cf17c6b94959d65f121a18faa8ae6ad8b8921b48700f5b6269df9d9b0e7049b22e04 SHA512 0c4a34f6ada5310af248c2e569900604c50295ecdcbc1dd7e5c4375cc68277ec9cac6786db8fa42d3783c2c68468cf88e0413fa60e4ac40d06818bfd34dcf09e
diff --git a/media-gfx/imagemagick/imagemagick-7.1.1.25.ebuild b/media-gfx/imagemagick/imagemagick-7.1.1.25.ebuild
new file mode 100644
index 000000000000..eb7f89a09b68
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.1.1.25.ebuild
@@ -0,0 +1,252 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QA_PKGCONFIG_VERSION=$(ver_cut 1-3)
+inherit autotools flag-o-matic perl-functions toolchain-funcs
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/ImageMagick/ImageMagick.git"
+	inherit git-r3
+	MY_P="imagemagick-9999"
+else
+	MY_PV="$(ver_rs 3 '-')"
+	MY_P="ImageMagick-${MY_PV}"
+	SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="https://www.imagemagick.org/"
+
+LICENSE="imagemagick"
+# Please check this on bumps, SONAME is often not updated! Use abidiff on old/new.
+# If ABI is broken, change the bit after the '-'.
+SLOT="0/$(ver_cut 1-3)-18"
+IUSE="bzip2 corefonts +cxx djvu fftw fontconfig fpx graphviz hardened hdri heif jbig jpeg jpeg2k jpegxl lcms lqr lzma opencl openexr openmp pango perl +png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zip zlib"
+
+REQUIRED_USE="
+	corefonts? ( truetype )
+	svg? ( xml )
+	test? ( corefonts )
+"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!media-gfx/graphicsmagick[imagemagick]
+	dev-libs/libltdl
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	heif? ( media-libs/libheif:=[x265] )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	jpegxl? ( >=media-libs/libjxl-0.6:= )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:= )
+	png? ( media-libs/libpng:= )
+	postscript? ( app-text/ghostscript-gpl:= )
+	raw? ( media-libs/libraw:= )
+	svg? (
+		gnome-base/librsvg
+		media-gfx/potrace
+	)
+	tiff? ( media-libs/tiff:= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+	)
+	webp? ( media-libs/libwebp:= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+	)
+	xml? ( dev-libs/libxml2 )
+	lzma? ( app-arch/xz-utils )
+	zip? ( dev-libs/libzip:= )
+	zlib? ( sys-libs/zlib:= )
+"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-9999-nocputuning.patch"
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	#elibtoolize # for Darwin modules
+	eautoreconf
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	local ati_cards mesa_cards nvidia_cards render_cards
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia* | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	use perl && perl_check_env
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		$(use_enable openmp)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zip)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with heif heic)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		$(use_with jpegxl jxl)
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with raw)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+
+		# Default upstream (as of 6.9.12.96/7.1.1.18 anyway) is open
+		# For now, let's make USE=hardened do 'limited', and have USE=-hardened
+		# reflect the upstream default of 'open'.
+		#
+		# We might change it to 'secure' and 'limited' at some point.
+		# See also bug #716674.
+		--with-security-policy=$(usex hardened limited open)
+	)
+
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	# Install default (unrestricted) policy in $HOME for test suite, bug #664238
+	local _im_local_config_home="${HOME}/.config/ImageMagick"
+	mkdir -p "${_im_local_config_home}" || \
+		die "Failed to create IM config dir in '${_im_local_config_home}'"
+	cp "${FILESDIR}"/policy.test.xml "${_im_local_config_home}/policy.xml" || \
+		die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
+
+	local im_command= IM_COMMANDS=()
+	if [[ ${PV} == 9999 ]] ; then
+		IM_COMMANDS+=( "magick -version" ) # Show version we are using -- cannot verify because of live ebuild
+	else
+		IM_COMMANDS+=( "magick -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
+	fi
+	IM_COMMANDS+=( "magick -list policy" ) # Verify that policy.xml is used
+	IM_COMMANDS+=( "emake check" ) # Run tests
+
+	for im_command in "${IM_COMMANDS[@]}"; do
+		eval "${S}"/magick.sh \
+			${im_command} || \
+			die "Failed to run \"${im_command}\""
+	done
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+	# .la files in parent are not needed, keep plugin .la files
+	find "${ED}"/usr/$(get_libdir)/ -maxdepth 1 -name "*.la" -delete || die
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/card0:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}