media-gfx/wkhtmltopdf: Add missing USE-dep

Also fixing GCC6 build warning.

Reported-by: Andreas Schürch <nativemad@gentoo.org>
Gentoo-bug: 631724
Package-Manager: Portage-2.3.10, Repoman-2.3.3

1 files changed, 50 insertions, 0 deletions

diff --git a/media-gfx/wkhtmltopdf/wkhtmltopdf-0.12.4-r1.ebuild b/media-gfx/wkhtmltopdf/wkhtmltopdf-0.12.4-r1.ebuild
new file mode 100644
index 000000000000..26b0e472f391
--- /dev/null
+++ b/media-gfx/wkhtmltopdf/wkhtmltopdf-0.12.4-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils
+
+DESCRIPTION="Convert html to pdf (and various image formats) using webkit"
+HOMEPAGE="https://wkhtmltopdf.org/ https://github.com/wkhtmltopdf/wkhtmltopdf/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebkit:5[printsupport]
+	dev-qt/qtwidgets:5
+"
+DEPEND="${RDEPEND}
+	dev-qt/qtxmlpatterns:5
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-build.patch
+	"${FILESDIR}"/${P}-gcc6-warn.patch
+)
+
+src_prepare() {
+	default
+	sed -i "s:\(INSTALLBASE/\)lib:\1$(get_libdir):" src/lib/lib.pro || die
+}
+
+src_configure() {
+	eqmake5 INSTALLBASE=/usr
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	use examples && dodoc -r examples
+	einstalldocs
+}