proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 50 insertions, 0 deletions

diff --git a/media-libs/raul/raul-0.8.0-r1.ebuild b/media-libs/raul/raul-0.8.0-r1.ebuild
new file mode 100644
index 000000000000..7a9d48cb21b7
--- /dev/null
+++ b/media-libs/raul/raul-0.8.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='threads(+)'
+
+inherit waf-utils python-any-r1 eutils
+
+DESCRIPTION="C++ utility library primarily aimed at audio/musical applications"
+HOMEPAGE="http://wiki.drobilla.net/Raul"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc test"
+
+RDEPEND="dev-libs/boost
+	>=dev-libs/glib-2.14.0"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+RAUL_TESTS="atomic_test atom_test list_test midi_ringbuffer_test path_test quantize_test queue_test ringbuffer_test smf_test table_test thread_test time_test"
+DOCS=( AUTHORS README ChangeLog )
+
+src_prepare() {
+	epatch "${FILESDIR}/ldconfig2.patch"
+	epatch "${FILESDIR}/${P}-gcc47.patch"
+}
+
+src_configure() {
+	waf-utils_src_configure \
+		--htmldir=/usr/share/doc/${PF}/html \
+		$(use debug && echo "--debug") \
+		$(use doc && echo "--docs") \
+		$(use test && echo "--test")
+}
+
+src_test() {
+	cd "${S}/build/test" || die
+	for i in ${RAUL_TESTS} ; do
+		einfo "Running test ${i}"
+		LD_LIBRARY_PATH=.. ./${i} || die
+	done
+}