proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 93 insertions, 0 deletions

diff --git a/media-sound/aqualung/aqualung-1.0_rc1.ebuild b/media-sound/aqualung/aqualung-1.0_rc1.ebuild
new file mode 100644
index 000000000000..e899a7702e84
--- /dev/null
+++ b/media-sound/aqualung/aqualung-1.0_rc1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils
+
+MY_PV=${PV/_/-}
+
+DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
+HOMEPAGE="http://aqualung.factorial.hu/"
+SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate lua
+	mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
+	vorbis wavpack"
+
+RDEPEND="sys-libs/zlib
+	app-arch/bzip2
+	dev-libs/libxml2
+	x11-libs/gtk+:2
+	alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	pulseaudio? ( media-sound/pulseaudio )
+	flac? ( media-libs/flac )
+	lame? ( media-sound/lame )
+	ffmpeg? ( >=virtual/ffmpeg-0.6.90 )
+	mac? ( media-sound/mac )
+	modplug? ( media-libs/libmodplug )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	mp3? ( media-libs/libmad )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
+	vorbis? ( media-libs/libvorbis media-libs/libogg )
+	wavpack? ( media-sound/wavpack )
+	ladspa? ( media-libs/liblrdf )
+	libsamplerate? ( media-libs/libsamplerate )
+	ifp? ( media-libs/libifp )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cddb? ( media-libs/libcddb )
+	lua? ( dev-lang/lua:0= )"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_configure() {
+	econf \
+		--enable-nls \
+		--disable-rpath \
+		$(use_enable debug) \
+		$(use_enable podcast) \
+		$(use_enable systray) \
+		--enable-transcoding \
+		$(use_enable jack jack-mgmt) \
+		--enable-loop \
+		$(use_with alsa) \
+		$(use_with jack) \
+		$(use_with oss) \
+		$(use_with pulseaudio pulse) \
+		$(use_with flac) \
+		$(use_with lame) \
+		$(use_with ffmpeg lavc) \
+		$(use_with mac) \
+		$(use_with modplug mod) \
+		$(use_with musepack mpc) \
+		$(use_with mp3 mpeg) \
+		$(use_with sndfile) \
+		$(use_with speex) \
+		$(use_with vorbis vorbis) \
+		$(use_with vorbis vorbisenc) \
+		$(use_with wavpack) \
+		$(use_with ladspa) \
+		$(use_with libsamplerate src) \
+		$(use_with cdda) \
+		$(use_with ifp) \
+		$(use_with cddb) \
+		$(use_with lua) \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	default
+
+	newicon src/img/icon_64.png aqualung.png
+	make_desktop_entry aqualung Aqualung
+}