media-sound/audacious: 4.0_beta1 version bump

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/media-sound/audacious/Manifest b/media-sound/audacious/Manifest
index 708576ef9542..be53df217598 100644
--- a/media-sound/audacious/Manifest
+++ b/media-sound/audacious/Manifest
@@ -1,3 +1,4 @@
 DIST audacious-3.10.1.tar.bz2 564481 BLAKE2B d1f76f34f0f6fbbe5ba92a95015fa0f3ef6399cc05f69f58474523761b00a4de7b8471660d9cb640487110cc3998df59f21108ff0b4ea72014ad75cd32ad864b SHA512 e88891caaa3897f9b4abf39136e20834aedf1287d0d5eefea392fda89050db8db00c6f363976a68fe250ddbae4e27590f7615916a76370a44ca9235f1fa60b43
 DIST audacious-3.9-gtk3.tar.bz2 600249 BLAKE2B 08559eafc85236e8e881d0cbe6f08e29c82baf0fc46b9209f1d3eee290460260bfa99e6e8f26940f8c6854f3782da24061226ebdb416b6249d10914093e16276 SHA512 6ff98d027c13b30ea9600a9aba914ec993c69826199b8dc303cb60cebdf2af06a7e3dd4af1d34a86343be5485848a57c8a29e48d2a45a33945585550de4e5f9c
+DIST audacious-4.0-beta1.tar.bz2 571077 BLAKE2B 5e47791e59b1f0abc149dfbc3f2727b2e7868e09a4f1a72720a5a07de3ef137030c69b77e3b8348d1db95ee4d7f986989e32903fe66c296fe99468688a8ceb64 SHA512 6696a18a29132eff6e0546883b76bd76af82931e43bff13786bc57e9e3ac36ea5c83b89155812c2c89b754779263e2528eb3423c34ba676790fcba3408a9240e
 DIST gentoo_ice-xmms-0.2.tar.bz2 51839 BLAKE2B d3bf8dbfee675dd588bc0258f1015c76877b6b0a3835813d8e9621d149b924aaa33544d07f7ad44a01c058d41d7480b3908b0773c124af33b6e020c376b13d54 SHA512 e863a8f86073007c47ce8c20739aae4bff22e22a7ddc11556b12ae6ebb68654cec7310fdc9d05f2c47f81cf2591fe601b2eb12a2fd911c0a6118c9f3cc524f05
diff --git a/media-sound/audacious/audacious-4.0_beta1.ebuild b/media-sound/audacious/audacious-4.0_beta1.ebuild
new file mode 100644
index 000000000000..2a75308519c1
--- /dev/null
+++ b/media-sound/audacious/audacious-4.0_beta1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/audacious-media-player/audacious.git"
+else
+	SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+inherit xdg
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="nls"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )
+"
+DEPEND="
+	>=dev-libs/dbus-glib-0.60
+	>=dev-libs/glib-2.28
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	>=x11-libs/cairo-1.2.6
+	>=x11-libs/pango-1.8.0
+	virtual/freedesktop-icon-theme
+"
+RDEPEND="${DEPEND}"
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	default
+	[[ ${PV} == *9999 ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+	default
+	if ! use nls; then
+		sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+	fi
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	# D-Bus is a mandatory dependency, remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	local myeconfargs=(
+		--disable-valgrind
+		--disable-gtk
+		--enable-dbus
+		--enable-qt
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins -r "${WORKDIR}"/gentoo_ice/.
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}