media-sound/bluez-alsa: Bump to version 3.0.0

Closes: https://bugs.gentoo.org/743016
Package-Manager: Portage-3.0.7, Repoman-3.0.1
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

3 files changed, 93 insertions, 0 deletions

diff --git a/media-sound/bluez-alsa/Manifest b/media-sound/bluez-alsa/Manifest
index 8d141d0c41f0..1f278685cce2 100644
--- a/media-sound/bluez-alsa/Manifest
+++ b/media-sound/bluez-alsa/Manifest
@@ -1 +1,2 @@
 DIST bluez-alsa-2.1.0.tar.gz 129650 BLAKE2B 6ab1b618828b5ad6f35c62a711cd24a51536ae4e013227addff8193bb522e0e7322d054fa8e688b5322ec59f6d08a654760ebb5792a637fa11536afc41c5dba5 SHA512 8b6d520f5733799b1c509052ac527377cbe5e0106b75180f783f83071246937b5dc7a22c2d27f3e9e331c52c74be59f3bc6d78caab97b41f06cfd6ed5191b584
+DIST bluez-alsa-3.0.0.tar.gz 157776 BLAKE2B 68cc67dcfd303e624333d7dafa53a3ce0f91f55e58a9a1a51f17153eadfdca5acc1b12b2e41a11c4780909fe8283e0a9c859a7d755e38dd9aeebbf4ae9e0daf2 SHA512 094c91636c3f1803b3eb88e295683acc604be9f86d00022c196784b4ec88aa4a6cc20bdff0fdab2a7e5af3efe95ed8bd8c5486a8cd7896ec572bfa9e8e0f13d0
diff --git a/media-sound/bluez-alsa/bluez-alsa-3.0.0.ebuild b/media-sound/bluez-alsa/bluez-alsa-3.0.0.ebuild
new file mode 100644
index 000000000000..3ab8343e3815
--- /dev/null
+++ b/media-sound/bluez-alsa/bluez-alsa-3.0.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal systemd
+
+DESCRIPTION="Bluetooth Audio ALSA Backend"
+HOMEPAGE="https://github.com/Arkq/bluez-alsa"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Arkq/${PN}"
+else
+	SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="aac debug hcitop lame ldac man mpg123 ofono static-libs test unwind upower"
+RESTRICT="!test? ( test )"
+
+# bluez-alsa does not directly link to upower but
+# is using the upower interface via dbus calls.
+RDEPEND="
+	>=dev-libs/glib-2.26[dbus,${MULTILIB_USEDEP}]
+	>=media-libs/alsa-lib-1.1.2[${MULTILIB_USEDEP}]
+	>=media-libs/sbc-1.2[${MULTILIB_USEDEP}]
+	>=net-wireless/bluez-5.0[${MULTILIB_USEDEP}]
+	sys-apps/dbus[${MULTILIB_USEDEP}]
+	sys-libs/readline:0=
+	aac? ( >=media-libs/fdk-aac-0.1.1:=[${MULTILIB_USEDEP}] )
+	lame? ( media-sound/lame[${MULTILIB_USEDEP}] )
+	mpg123? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	hcitop? (
+		dev-libs/libbsd
+		sys-libs/ncurses:0=
+	)
+	ldac? ( >=media-libs/libldac-2.0.0 )
+	ofono? ( net-misc/ofono )
+	unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
+	upower? ( sys-power/upower )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )"
+BDEPEND="
+	virtual/pkgconfig
+	man? ( app-text/pandoc )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-rfcomm
+		$(use_enable aac)
+		$(use_enable debug)
+		$(use_enable lame mp3lame)
+		$(use_enable man manpages)
+		$(use_enable mpg123)
+		$(use_enable static-libs static)
+		$(use_enable test)
+		$(multilib_native_use_enable hcitop)
+		$(multilib_native_use_enable ldac)
+		$(multilib_native_use_enable ofono)
+		$(multilib_native_use_enable upower)
+		$(use_with unwind libunwind)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
+	newconfd "${FILESDIR}"/bluealsa-conf.d-2 bluealsa
+	systemd_dounit "${FILESDIR}"/bluealsa.service
+
+	# Add config file to alsa datadir as well to preserve changes in /etc
+	insinto "/usr/share/alsa/alsa.conf.d/"
+	doins "src/asound/20-bluealsa.conf"
+}
+
+pkg_postinst() {
+	elog "Users can use this service when they are members of the \"audio\" group."
+}
diff --git a/media-sound/bluez-alsa/metadata.xml b/media-sound/bluez-alsa/metadata.xml
index 4fa05b5a0f0c..cf14e256b358 100644
--- a/media-sound/bluez-alsa/metadata.xml
+++ b/media-sound/bluez-alsa/metadata.xml
@@ -11,6 +11,8 @@
   <use>
     <flag name="hcitop">Enable top-like monitoring tool for HCI</flag>
     <flag name="ldac">Enable support for AOSP <pkg>media-libs/libldac</pkg> dispatcher</flag>
+    <flag name="man">Generate (and install) man pages with <pkg>app-text/pandoc</pkg></flag>
+    <flag name="mpg123">Enable support for MPEG audio playback via <pkg>media-sound/mpg123</pkg></flag>
     <flag name="ofono">Enable ofono elephony support</flag>
   </use>
 </pkgmetadata>