media-sound/elisa: EAPI-7 bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/media-sound/elisa/elisa-0.3.0-r1.ebuild b/media-sound/elisa/elisa-0.3.0-r1.ebuild
new file mode 100644
index 000000000000..179c74eabb5a
--- /dev/null
+++ b/media-sound/elisa/elisa-0.3.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+KDE_HANDBOOK="optional"
+inherit kde5
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Simple music player by KDE"
+HOMEPAGE="https://community.kde.org/Elisa"
+LICENSE="LGPL-3+"
+IUSE="mpris semantic-desktop"
+
+BDEPEND="
+	sys-devel/gettext
+"
+DEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kfilemetadata)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtmultimedia 'gstreamer')
+	$(add_qt_dep qtsql)
+	$(add_qt_dep qtwidgets)
+	mpris? (
+		$(add_frameworks_dep kdbusaddons)
+		$(add_qt_dep qtdbus)
+	)
+	semantic-desktop? (
+		$(add_frameworks_dep baloo)
+	)
+"
+RDEPEND="${DEPEND}
+	$(add_qt_dep qtgraphicaleffects)
+	$(add_qt_dep qtquickcontrols)
+	$(add_qt_dep qtquickcontrols2)
+"
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package mpris KF5DBusAddons)
+		$(cmake-utils_use_find_package semantic-desktop KF5Baloo)
+	)
+
+	kde5_src_configure
+}