media-sound/hydrogen: bump to 1.0.0

Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

4 files changed, 98 insertions, 1 deletions

diff --git a/media-sound/hydrogen/Manifest b/media-sound/hydrogen/Manifest
index 5b7804a6568f..ca4de0a35940 100644
--- a/media-sound/hydrogen/Manifest
+++ b/media-sound/hydrogen/Manifest
@@ -1 +1,2 @@
+DIST hydrogen-1.0.0.tar.gz 11501728 BLAKE2B ccb48cddff2b196e934c712f999109ae4b91513579ec123e57f2ef9f6aa288c1408208bde8608a908e58650c741260fbcc1108dabd7968687d74e4c143fb7de3 SHA512 68a7634a63d409ff8eef789bb9dd86b65535e17b6101fe1e1bd0153cab4852dc2cfa7ff11b2cfddbead337d2faad9ca4c49eed589c47c09aa5f5aa91c59171a7
 DIST hydrogen-1.0.0_rc1.tar.gz 11502829 BLAKE2B 2d529c94713f415af1b183ff8dd11d05111da1cfac130eea749aaa5c5fa941bc69b172bdc77cf755ad3a34617609af28690cd94bc975feab3ecb06af6e7965f8 SHA512 1615956ed02cfc0553ff09b651f76cb56dd35ec314a535fcb97f9658eebb6eee3eba884779b097767b404c82d6e074e2df342bdaabce77a47ad8278bd18be1be
diff --git a/media-sound/hydrogen/files/hydrogen-9999-gnuinstalldirs.patch b/media-sound/hydrogen/files/hydrogen-1.0.0-gnuinstalldirs.patch
index 9b8429753072..9b8429753072 100644
--- a/media-sound/hydrogen/files/hydrogen-9999-gnuinstalldirs.patch
+++ b/media-sound/hydrogen/files/hydrogen-1.0.0-gnuinstalldirs.patch
diff --git a/media-sound/hydrogen/hydrogen-1.0.0.ebuild b/media-sound/hydrogen/hydrogen-1.0.0.ebuild
new file mode 100644
index 000000000000..bfd663bbc555
--- /dev/null
+++ b/media-sound/hydrogen/hydrogen-1.0.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Advanced drum machine"
+HOMEPAGE="http://www.hydrogen-music.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}-music/${PN}"
+	KEYWORDS=""
+else
+	MY_PV=${PV/_/-}
+	SRC_URI="https://github.com/${PN}-music/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+fi
+
+LICENSE="GPL-2 ZLIB"
+SLOT="0"
+IUSE="alsa +archive doc jack ladspa lash osc oss portaudio portmidi pulseaudio"
+
+REQUIRED_USE="lash? ( alsa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+CDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	>=media-libs/libsndfile-1.0.18
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	!archive? ( >=dev-libs/libtar-1.2.11-r3 )
+	jack? ( virtual/jack )
+	ladspa? ( media-libs/liblrdf )
+	lash? ( media-sound/lash )
+	osc? ( media-libs/liblo )
+	portaudio? ( media-libs/portaudio )
+	portmidi? ( media-libs/portmidi )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+DEPEND="
+	${CDEPEND}
+	dev-qt/qttest:5
+"
+RDEPEND="${CDEPEND}"
+
+DOCS=( AUTHORS ChangeLog DEVELOPERS README.txt )
+
+PATCHES=( "${FILESDIR}/${P}-gnuinstalldirs.patch" )
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWANT_ALSA=$(usex alsa)
+		-DWANT_CPPUNIT=OFF
+		-DWANT_DEBUG=OFF
+		-DWANT_JACK=$(usex jack)
+		-DWANT_JACKSESSION=$(usex jack)
+		-DWANT_LADSPA=$(usex ladspa)
+		-DWANT_LASH=$(usex lash)
+		-DWANT_LIBARCHIVE=$(usex archive)
+		-DWANT_LRDF=$(usex ladspa)
+		-DWANT_OSC=$(usex osc)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PORTAUDIO=$(usex portaudio)
+		-DWANT_PORTMIDI=$(usex portmidi)
+		-DWANT_PULSEAUDIO=$(usex pulseaudio)
+		-DWANT_RUBBERBAND=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/docs/html/. )
+	cmake_src_install
+}
diff --git a/media-sound/hydrogen/hydrogen-9999.ebuild b/media-sound/hydrogen/hydrogen-9999.ebuild
index bfd663bbc555..245dc874f114 100644
--- a/media-sound/hydrogen/hydrogen-9999.ebuild
+++ b/media-sound/hydrogen/hydrogen-9999.ebuild
@@ -57,7 +57,7 @@ RDEPEND="${CDEPEND}"
 
 DOCS=( AUTHORS ChangeLog DEVELOPERS README.txt )
 
-PATCHES=( "${FILESDIR}/${P}-gnuinstalldirs.patch" )
+PATCHES=( "${FILESDIR}/${PN}-1.0.0-gnuinstalldirs.patch" )
 
 src_prepare() {
 	cmake_src_prepare