media-video/aravis: bump 0.7.2

Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: Bernardo Meurer <bernardo@standard.ai>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 71 insertions, 22 deletions

diff --git a/media-video/aravis/Manifest b/media-video/aravis/Manifest
index 5deae26c664e..568548bd4d01 100644
--- a/media-video/aravis/Manifest
+++ b/media-video/aravis/Manifest
@@ -1 +1,2 @@
 DIST aravis-0.6.4.tar.gz 2972111 BLAKE2B b7f1c4da08bb4e7d11faffcd4ef90b7215b803e5e74ba1730388e04304685b761024ffea49b082c94e3fddc9dc65201545167a277b1088ad7273d41d50fae5b0 SHA512 6090fd730ad9fe8e1641e48c52189e8961bf03a88cefb57135a2de985c2ca607c21b05d472a60586976aa1e05ba2121246b06b75179dd3241e1f703aad8dd7be
+DIST aravis-0.7.2.tar.gz 940928 BLAKE2B 67b6772aaf6195e393caf2f3fcf6d24acace9d7160023c801f93d479e9d488e4082dcd11d40a8db18dea6cd516e0b24cb78e46de09d455a3c822208d9f33af5b SHA512 5cc6c01f77462c595a87a5899df752a5018e72b4de108fc3bcebbb39542482fc535401a7f10732270d98998fe807c929ae9e7750cc7ac0ce089763d1eb148e2a
diff --git a/media-video/aravis/aravis-0.7.2.ebuild b/media-video/aravis/aravis-0.7.2.ebuild
new file mode 100644
index 000000000000..f2dd9137fe00
--- /dev/null
+++ b/media-video/aravis/aravis-0.7.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit meson xdg
+
+DESCRIPTION="Library for video acquisition using Genicam cameras"
+HOMEPAGE="https://github.com/AravisProject/aravis"
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/AravisProject/${PN}"
+else
+	MY_P="${PN^^}_${PV//./_}"
+	SRC_URI="https://github.com/AravisProject/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2+"
+SLOT="0"
+# FIXME: As of right now tests are always built, once that changes a USE flag
+# should be added. c.f. https://github.com/AravisProject/aravis/issues/286
+IUSE="gtk-doc fast-heartbeat gstreamer introspection packet-socket usb viewer"
+
+GST_DEPEND="
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="
+	dev-libs/glib:2[gtk-doc?]
+	dev-libs/libxml2:2
+	sys-libs/zlib
+	gstreamer? ( ${GST_DEPEND} )
+	packet-socket? ( sys-process/audit )
+	usb? ( virtual/libusb:1 )
+	viewer? (
+		${GST_DEPEND}
+		x11-libs/gtk+:3
+		x11-libs/libnotify
+	)
+"
+RDEPEND="${DEPEND}"
+
+if [[ ${PV} != 9999 ]]; then
+	S="${WORKDIR}/${PN}-${MY_P}"
+fi
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc documentation)
+		$(meson_use fast-heartbeat)
+		$(meson_use gstreamer gst-plugin)
+		$(meson_use introspection)
+		$(meson_use packet-socket)
+		$(meson_use usb)
+		$(meson_use viewer)
+	)
+	meson_src_configure
+}
diff --git a/media-video/aravis/aravis-9999.ebuild b/media-video/aravis/aravis-9999.ebuild
index 5ffb500be0c2..f2dd9137fe00 100644
--- a/media-video/aravis/aravis-9999.ebuild
+++ b/media-video/aravis/aravis-9999.ebuild
@@ -36,7 +36,7 @@ BDEPEND="
 	introspection? ( dev-libs/gobject-introspection:= )
 "
 DEPEND="
-	>=dev-libs/glib-2.34:2
+	dev-libs/glib:2[gtk-doc?]
 	dev-libs/libxml2:2
 	sys-libs/zlib
 	gstreamer? ( ${GST_DEPEND} )
@@ -44,7 +44,7 @@ DEPEND="
 	usb? ( virtual/libusb:1 )
 	viewer? (
 		${GST_DEPEND}
-		>=x11-libs/gtk+-3.12:3
+		x11-libs/gtk+:3
 		x11-libs/libnotify
 	)
 "
@@ -66,23 +66,3 @@ src_configure() {
 	)
 	meson_src_configure
 }
-
-src_install() {
-	meson_src_install
-	# Aravis appends the major and min versions (but not the patch) to it's
-	# binaries and it's folder in /usr/share. Things then end up like
-	# `arv-tool-0.6`. We use this little hack to find out the version of the
-	# current build in a way that works even for a -9999 ebuild.
-	local install_pv="$(ls ${ED}/usr/share | grep aravis- | cut -f 2 -d '-')"
-	local install_p="${PN}-${install_pv}"
-
-	# Properly place icons
-	if use viewer; then
-		cp -r "${ED}/usr/share/${install_p}/icons" "${ED}/usr/share" || die "Failed to copy icons"
-	fi
-
-	# Symlink versioned binaries to non-versioned
-	dosym "arv-tool-${install_pv}" "usr/bin/arv-tool"
-	dosym "arv-fake-gv-camera-${install_pv}" "usr/bin/arv-fake-gv-camera"
-	use viewer && dosym "arv-viewer-${install_pv}" "usr/bin/arv-viewer"
-}