media-video/obs-studio: remove version 27.2.0

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/24323
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 0 insertions, 207 deletions

diff --git a/media-video/obs-studio/Manifest b/media-video/obs-studio/Manifest
index 605ed4883baa..b5afb6939d0d 100644
--- a/media-video/obs-studio/Manifest
+++ b/media-video/obs-studio/Manifest
@@ -2,7 +2,5 @@ DIST cef_binary_4280_linux64.tar.bz2 79740715 BLAKE2B c648a9a4205094450f9eae407e
 DIST cef_binary_4638_linux64.tar.bz2 104578246 BLAKE2B 13ee05d4a2fbf27290506297416b298c786954450c19183b493d13aa691db409c22b30870fbc55adf814ff30142a666eb8b172f16ccc48e6cf01135c72e5d6d6 SHA512 2eb01151e07adf332affce36a659c6e87da1fbc403c65db7e7c53472ff418df6cd04300a7c6ebc8789c094926429cc70d829e556e5de3127da230f8258fabe49
 DIST obs-browser-915761778ec1eae99e740ad4bf63b40db3142ee2.tar.gz 100021 BLAKE2B d72df588aaeaf199c6ea5a7e419bb4792ef8b4c4237e700f75064d96caaec83ed2be2ea4ab34ba31e30a87ec6cbf1f267dd7b100c3a6cfec36e46b2eca8c4b2e SHA512 3ab6118a9509054ea4e8aed14dade7f374495ba25fcb5295a3ef7ed29e6e3305b0ae2f12ba2c0d27fcd6886822c98ab44a48fa9a4b66ae0507ab2bf1001157cb
 DIST obs-browser-aee43000bd994022cd73e32dc50938ab777d4a06.tar.gz 89603 BLAKE2B a51b92f829ecb7055dcf969d6d5bdc4632b51288f0bc7e2ab66fda087da608869ddffccda83aa925f049c79e745a6f67e70ec72303184b970f5009fe37b34054 SHA512 8159ca02b5c30d2733ce8e566f21d6b77d6b7beabd0a5898049ee83b0b4d720b967fc55fcf876cd772fdaa12ca08163a0f8cabf249a9b3b6eb56b7666d1192c7
-DIST obs-browser-b0d687937af876b52b69c46e276b4ab601b07f0e.tar.gz 99899 BLAKE2B 2787ce1a652432cd3637f3af782ce2db6d9fda0d2d7a20b42cc4f51365b8b53dcd9101aaccc70e42ce770b36a4d3a993c540215d571dbfe81762aa2291211feb SHA512 e7df0ea4ecf4cdbb2c6b20742c40e1e9f5941c505d69b6c749ab9b2016a4066dc6c5bdd5942f35fd0b1f628e201ac1c4888910658535605a7471a5815cf9a337
 DIST obs-studio-27.1.3.tar.gz 15994678 BLAKE2B 5544a1ecdb04dca7f6422936ea5499a206b4beb8e5332605c18cd72a91ce73aa74ff06c49a106931822c1c413ee94d383942f173a71f2b21168a00495b4e301f SHA512 04c11c79e3b091aa9ea8fc6674c9fbcaa1c924fe049f68e9be63f63724c31305d6e4fb33aecdd4d0095d20013e2ee188983f6938b175257368d2260681c2fb39
-DIST obs-studio-27.2.0.tar.gz 16382704 BLAKE2B 9628467a706b076896aeac26b06f3cca0ebfcce110c8862bb62bc81129300d2ec710cd2768a5d6b526a40b21e08f77135b7146c18f58303e50ab837c0e7885a0 SHA512 0f56e12d429c3208a9d200d085606dd401952a9a37d03ecf70e46d932fb8e907906b53c3a4ea7c9e10a3cbb3001bbd569163457d5bcb41eb8cce984b3c2b4d90
 DIST obs-studio-27.2.1.tar.gz 16382458 BLAKE2B 065ee7c97d07ba57bc0709b0e1f4ea07114053ad7bcaf1be868bc4759e596f4cb8dd9fffe5040dcd9d507ccc980b4a56f08ad8a574297d0ff7f70c0db9bc5e62 SHA512 8992d2d8cb13e82e457a844d9ff63d57ab854a8c6f295563f86009cab801845fb093d39d315c14ef333a7a9908928ac15af4d0454ea570da4a98aff5f25f89af
diff --git a/media-video/obs-studio/obs-studio-27.2.0.ebuild b/media-video/obs-studio/obs-studio-27.2.0.ebuild
deleted file mode 100644
index 886f44b7284f..000000000000
--- a/media-video/obs-studio/obs-studio-27.2.0.ebuild
+++ /dev/null
@@ -1,205 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit cmake lua-single python-single-r1 xdg
-
-OBS_BROWSER_COMMIT="b0d687937af876b52b69c46e276b4ab601b07f0e"
-CEF_DIR="cef_binary_4638_linux64"
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
-	EGIT_SUBMODULES=( plugins/obs-browser )
-else
-	SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	SRC_URI+=" browser? ( https://github.com/obsproject/obs-browser/archive/${OBS_BROWSER_COMMIT}.tar.gz -> obs-browser-${OBS_BROWSER_COMMIT}.tar.gz )"
-	KEYWORDS="~amd64 ~ppc64 ~x86"
-fi
-SRC_URI+=" browser? ( https://cdn-fastly.obsproject.com/downloads/${CEF_DIR}.tar.bz2 )"
-
-DESCRIPTION="Software for Recording and Streaming Live Video Content"
-HOMEPAGE="https://obsproject.com"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="
-	+alsa browser decklink fdk jack lua nvenc pipewire
-	pulseaudio python speex +ssl truetype v4l vlc wayland
-"
-REQUIRED_USE="
-	browser? ( || ( alsa pulseaudio ) )
-	lua? ( ${LUA_REQUIRED_USE} )
-	python? ( ${PYTHON_REQUIRED_USE} )
-"
-
-BDEPEND="
-	lua? ( dev-lang/swig )
-	python? ( dev-lang/swig )
-"
-DEPEND="
-	dev-libs/glib:2
-	dev-libs/jansson:=
-	dev-qt/qtcore:5
-	dev-qt/qtdeclarative:5
-	dev-qt/qtgui:5[wayland?]
-	dev-qt/qtmultimedia:5
-	dev-qt/qtnetwork:5
-	dev-qt/qtquickcontrols:5
-	dev-qt/qtsql:5
-	dev-qt/qtsvg:5
-	dev-qt/qtwidgets:5
-	dev-qt/qtx11extras:5
-	dev-qt/qtxml:5
-	media-libs/libglvnd
-	media-libs/x264:=
-	media-video/ffmpeg:=[x264]
-	net-misc/curl
-	sys-apps/dbus
-	sys-apps/pciutils
-	sys-libs/zlib:=
-	virtual/udev
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXfixes
-	x11-libs/libXinerama
-	x11-libs/libXrandr
-	x11-libs/libxcb:=
-	alsa? ( media-libs/alsa-lib )
-	browser? (
-		app-accessibility/at-spi2-atk
-		app-accessibility/at-spi2-core:2
-		dev-libs/atk
-		dev-libs/expat
-		dev-libs/glib
-		dev-libs/nspr
-		dev-libs/nss
-		media-libs/alsa-lib
-		media-libs/fontconfig
-		media-libs/mesa[gbm(+)]
-		net-print/cups
-		x11-libs/cairo
-		x11-libs/libdrm
-		x11-libs/libXScrnSaver
-		x11-libs/libXcursor
-		x11-libs/libXdamage
-		x11-libs/libXext
-		x11-libs/libXi
-		x11-libs/libXrender
-		x11-libs/libXtst
-	)
-	fdk? ( media-libs/fdk-aac:= )
-	jack? ( virtual/jack )
-	lua? ( ${LUA_DEPS} )
-	nvenc? ( >=media-video/ffmpeg-4[video_cards_nvidia] )
-	pipewire? ( media-video/pipewire:= )
-	pulseaudio? ( media-sound/pulseaudio )
-	python? ( ${PYTHON_DEPS} )
-	speex? ( media-libs/speexdsp )
-	ssl? ( net-libs/mbedtls:= )
-	truetype? (
-		media-libs/fontconfig
-		media-libs/freetype
-	)
-	v4l? ( media-libs/libv4l )
-	vlc? ( media-video/vlc:= )
-	wayland? ( dev-libs/wayland )
-"
-RDEPEND="${DEPEND}"
-
-QA_PREBUILT="
-	usr/lib*/obs-plugins/chrome-sandbox
-	usr/lib*/obs-plugins/libcef.so
-	usr/lib*/obs-plugins/libEGL.so
-	usr/lib*/obs-plugins/libGLESv2.so
-	usr/lib*/obs-plugins/libvk_swiftshader.so
-	usr/lib*/obs-plugins/libvulkan.so.1
-	usr/lib*/obs-plugins/swiftshader/libEGL.so
-	usr/lib*/obs-plugins/swiftshader/libGLESv2.so
-"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	use python && python-single-r1_pkg_setup
-}
-
-src_unpack() {
-	default
-
-	if [[ ${PV} == 9999 ]]; then
-		git-r3_src_unpack
-	elif use browser; then
-		rm -d ${P}/plugins/obs-browser || die
-		mv obs-browser-${OBS_BROWSER_COMMIT} ${P}/plugins/obs-browser || die
-	fi
-}
-
-src_configure() {
-	local libdir=$(get_libdir)
-	local mycmakeargs=(
-		$(usev browser -DCEF_ROOT_DIR=../${CEF_DIR})
-		-DBUILD_BROWSER=$(usex browser)
-		-DBUILD_VST=no
-		-DENABLE_WAYLAND=$(usex wayland)
-		-DDISABLE_ALSA=$(usex !alsa)
-		-DDISABLE_DECKLINK=$(usex !decklink)
-		-DDISABLE_FREETYPE=$(usex !truetype)
-		-DDISABLE_JACK=$(usex !jack)
-		-DDISABLE_LIBFDK=$(usex !fdk)
-		-DENABLE_PIPEWIRE=$(usex pipewire)
-		-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
-		-DDISABLE_SPEEXDSP=$(usex !speex)
-		-DDISABLE_V4L2=$(usex !v4l)
-		-DDISABLE_VLC=$(usex !vlc)
-		-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
-		-DUNIX_STRUCTURE=1
-		-DWITH_RTMPS=$(usex ssl)
-
-		# deprecated and currently cause issues
-		# https://github.com/obsproject/obs-studio/pull/4560#issuecomment-826345608
-		-DLIBOBS_PREFER_IMAGEMAGICK=no
-	)
-
-	if [[ ${PV} != 9999 ]]; then
-		mycmakeargs+=(
-			-DOBS_VERSION_OVERRIDE=${PV}
-		)
-	fi
-
-	if use lua || use python; then
-		mycmakeargs+=(
-			-DDISABLE_LUA=$(usex !lua)
-			-DDISABLE_PYTHON=$(usex !python)
-			-DENABLE_SCRIPTING=yes
-		)
-	else
-		mycmakeargs+=( -DENABLE_SCRIPTING=no )
-	fi
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	# external plugins may need some things not installed by default, install them here
-	insinto /usr/include/obs/UI/obs-frontend-api
-	doins UI/obs-frontend-api/obs-frontend-api.h
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if ! use alsa && ! use pulseaudio; then
-		elog
-		elog "For the audio capture features to be available,"
-		elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
-		elog "be enabled."
-		elog
-	fi
-}