proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 53 insertions, 0 deletions

diff --git a/net-analyzer/tcpflow/tcpflow-1.4.4_p3.ebuild b/net-analyzer/tcpflow/tcpflow-1.4.4_p3.ebuild
new file mode 100644
index 000000000000..7cb285e3fa98
--- /dev/null
+++ b/net-analyzer/tcpflow/tcpflow-1.4.4_p3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils
+
+DESCRIPTION="A tool for monitoring, capturing and storing TCP connections flows"
+HOMEPAGE="https://github.com/simsong/tcpflow http://packages.qa.debian.org/t/tcpflow.html"
+SRC_URI="
+	mirror://debian/pool/main/t/${PN}/${PN}_${PV/_p*}+repack1.orig.tar.gz
+	mirror://debian/pool/main/t/${PN}/${PN}_${PV/_p*}+repack1-${PV/*_p}.debian.tar.xz
+"
+
+LICENSE="GPL-3"
+KEYWORDS="amd64 ~arm ppc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+SLOT="0"
+IUSE="cairo +pcap test"
+
+RDEPEND="
+	app-forensics/afflib
+	dev-libs/boost
+	dev-libs/openssl
+	net-libs/http-parser
+	pcap? ( net-libs/libpcap )
+	sys-libs/zlib
+	cairo? (
+		x11-libs/cairo
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? ( sys-apps/coreutils )
+"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch "${WORKDIR}"/debian/patches/*.patch
+
+	mv -f README{.md,} || die
+
+	sed -i -e 's:`md5 -q \(.*\)`:`md5sum \1 | cut -f1 -d" "`:' tests/*.sh || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(usex pcap --enable-pcap=true --enable-pcap=false) \
+		$(usex cairo --enable-cairo=true --enable-cairo=false) \
+		--without-o3
+}