net-dns/pdns-recursor: Version bump to 4.4.4 and 4.5.2

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Sven Wegener <swegener@gentoo.org>

3 files changed, 172 insertions, 0 deletions

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index e5fd3f39f086..ba395ca18f5a 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1,2 +1,4 @@
 DIST pdns-recursor-4.4.3.tar.bz2 1398743 BLAKE2B d9429ef22bb2b196e42da91332332b38dee9220d490c8adda686b0bc144e0981ea4418973f4304d6d964ef8f6ac4adcde4bd3e6d6b208c620440eab1b11a7fc0 SHA512 bac69cbaabc1b0de0def681e07f7e77954e0d487732cb46dc722f7869576a8a477a4011f78c9cc66b5e9b45455eb81534602b2834dc1ad42b85f5f2801915cbb
+DIST pdns-recursor-4.4.4.tar.bz2 1399645 BLAKE2B 2ef2a59b9c402ab9d9b59d6b89e85b7103dbd9cdcc6147d08f09b85209cb2e298ff539dcb24895a4711f4e7c55c398d0307f237b22d1bdadaf01ec3925af0e8f SHA512 de8ac38d77a4700cd9dd64aad2ba7d1a97057683ace34f1dc3b2e9680faef5637ce7cedb66ceb0b7701f7ff6ef80cbee653549302805b30f9a6defa3a4e8e830
 DIST pdns-recursor-4.5.1.tar.bz2 1463138 BLAKE2B 863cddbe4001b32cf457dc489bd39ad7b045f19183b1d13bc31bfd7fa28cc6e7e69755216715e0fd75fd0d724de20f7b89c89017fc42dff35de4e45e9351af75 SHA512 0cfbc95e3e84a2ab2cd88ee638b0ff26f5f35b64754086483555df28f045d64b5fdfab3e8c430c0b4e97dc4eda624226c37ec0f50902ffe5f84882d814e8051e
+DIST pdns-recursor-4.5.2.tar.bz2 1464834 BLAKE2B 88acd7a6edecf8188b366a9fcff0eaf1b71429df8aad4dbcf157be39901b56ee3c9a9d55bf55bb060bcbb59f68b3ff8987788f4186a7122787874f895be1e751 SHA512 02a9f725c7528f91eb45409b32ffa06cb7fca1f0151907efcd8b75100942e98f593858543df15423413d69c9fd433bad3c8bad0a84f8144af07c637f22a86d5e
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.4.4.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.4.4.ebuild
new file mode 100644
index 000000000000..dc546d8cd6ca
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.4.4.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap protobuf snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}
+	dnstap? ( protobuf )"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	protobuf? (
+		dev-libs/protobuf
+		>=dev-libs/boost-1.42:=
+	)
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	dev-libs/openssl:=
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with protobuf) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.5.2.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.5.2.ebuild
new file mode 100644
index 000000000000..391869be2aec
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.5.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug dnstap snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	dev-libs/openssl:=
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}