net-im/dino: add 0.4.0

Bug: https://bugs.gentoo.org/851765
Closes: https://bugs.gentoo.org/869971

Signed-off-by: Michael Vetter <jubalh@iodoru.org>
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 102 insertions, 7 deletions

diff --git a/net-im/dino/Manifest b/net-im/dino/Manifest
index 20cbe5460593..ed37f9d9df06 100644
--- a/net-im/dino/Manifest
+++ b/net-im/dino/Manifest
@@ -1 +1,2 @@
 DIST dino-0.3.0.tar.gz 804810 BLAKE2B cb6365f6fad051d0308909c6d5d2c59d7f57cb94f9f691516e27b7bb3aba214fdffa95066d8203d8ac5bd770bec1580e81baad313beef7fe5c058e1e94a37556 SHA512 e3d885208451b00b0416a1401780a94a169fb1179b2f609f7965e3445873d6b72ded84cb471d534616892ec89b5edcd6701fc97c36f19d690f4b894399000515
+DIST dino-0.4.0.tar.gz 882288 BLAKE2B 7d05f358746c09d5c129db1366fdb609f796cdc11c889bc22f9d0d71daa1b9b622b83512e15cbfe8d1e6f3fcf2870f20d7e0c5ecbf66257e7a155d2e020f7652 SHA512 09abfda34625a680dd7bc4cfa842c6bcbc4097fa613bf91bb7c6a4a10d2075f5050d3be705379fd7ecf9c686024000cd6791757eb8b0958ff8e533774267085a
diff --git a/net-im/dino/dino-0.4.0.ebuild b/net-im/dino/dino-0.4.0.ebuild
new file mode 100644
index 000000000000..25abd0156494
--- /dev/null
+++ b/net-im/dino/dino-0.4.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake vala xdg readme.gentoo-r1
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +omemo +notification-sound test"
+RESTRICT="!test? ( test )"
+
+MY_REPO_URI="https://github.com/dino/dino"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="${MY_REPO_URI}.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~arm64"
+	SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
+fi
+
+RDEPEND="
+	app-text/gspell[vala]
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu:=
+	dev-libs/libgee:0.8=
+	gui-libs/gtk:4
+	>=gui-libs/libadwaita-1.2.0:1
+	net-libs/glib-networking
+	>=net-libs/libnice-0.1.15
+	net-libs/libsignal-protocol-c
+	net-libs/libsrtp:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	gpg? ( app-crypt/gpgme:= )
+	http? ( net-libs/libsoup:2.4 )
+	notification-sound? ( media-libs/libcanberra:0[sound] )
+	omemo? (
+		dev-libs/libgcrypt:=
+		media-gfx/qrencode:=
+	)
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+"
+BDEPEND="
+	sys-devel/gettext
+	$(vala_depend)
+"
+
+src_configure() {
+	vala_setup
+
+	# TODO: Make videocalls (rtp) optional and not completely disable it
+	local disabled_plugins=(
+		$(usex gpg "" "openpgp")
+		$(usex omemo "" "omemo")
+		$(usex http  "" "http-files")
+		"rtp"
+	)
+	local enabled_plugins=(
+		$(usex notification-sound "notification-sound" "")
+	)
+	local mycmakeargs=(
+		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
+		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
+		"-DVALA_EXECUTABLE=${VALAC}"
+		"-DBUILD_TESTS=$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/xmpp-vala-test || die
+}
+
+src_install() {
+	cmake_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}
diff --git a/net-im/dino/dino-9999.ebuild b/net-im/dino/dino-9999.ebuild
index 5362d42a0864..06edb44323fe 100644
--- a/net-im/dino/dino-9999.ebuild
+++ b/net-im/dino/dino-9999.ebuild
@@ -26,23 +26,24 @@ RDEPEND="
 	app-text/gspell[vala]
 	dev-db/sqlite:3
 	dev-libs/glib:2
-	dev-libs/icu
-	dev-libs/libgee:0.8
+	dev-libs/icu:=
+	dev-libs/libgee:0.8=
+	gui-libs/gtk:4
+	>=gui-libs/libadwaita-1.2.0:1
 	net-libs/glib-networking
 	>=net-libs/libnice-0.1.15
 	net-libs/libsignal-protocol-c
 	net-libs/libsrtp:2
 	x11-libs/cairo
 	x11-libs/gdk-pixbuf:2
-	x11-libs/gtk+:3
 	x11-libs/pango
 	gpg? ( app-crypt/gpgme:= )
 	http? ( net-libs/libsoup:2.4 )
+	notification-sound? ( media-libs/libcanberra:0[sound] )
 	omemo? (
-		dev-libs/libgcrypt:0
-		media-gfx/qrencode
+		dev-libs/libgcrypt:=
+		media-gfx/qrencode:=
 	)
-	notification-sound? ( media-libs/libcanberra:0[sound] )
 "
 DEPEND="
 	${RDEPEND}
@@ -65,7 +66,7 @@ src_configure() {
 	local enabled_plugins=(
 		$(usex notification-sound "notification-sound" "")
 	)
-	local mycmakeargs+=(
+	local mycmakeargs=(
 		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
 		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
 		"-DVALA_EXECUTABLE=${VALAC}"