net-libs/libisds: version bump 0.10.7 bug #624362

Submitted-by: Petr Pisar <petr.pisar@atlas.cz>

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 54 insertions, 0 deletions

diff --git a/net-libs/libisds/libisds-0.10.7.ebuild b/net-libs/libisds/libisds-0.10.7.ebuild
new file mode 100644
index 000000000000..f0c245e83cd7
--- /dev/null
+++ b/net-libs/libisds/libisds-0.10.7.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Client library for accessing ISDS Soap services"
+HOMEPAGE="http://xpisar.wz.cz/libisds/"
+SRC_URI="http://xpisar.wz.cz/${PN}/dist/${P}.tar.xz"
+KEYWORDS="~amd64 ~mips ~x86"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="+curl debug nls openssl static-libs test"
+
+COMMON_DEPEND="
+	dev-libs/expat
+	dev-libs/libxml2
+	curl? ( net-misc/curl[ssl] )
+	openssl? ( dev-libs/openssl:= )
+	!openssl? (
+		app-crypt/gpgme
+		dev-libs/libgcrypt:=
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( >=net-libs/gnutls-2.12.0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!openssl? ( >=app-crypt/gnupg-2 )
+"
+
+DOCS=( NEWS README AUTHORS ChangeLog )
+
+src_configure() {
+	local myeconfargs=(
+		--disable-fatalwarnings
+		$(use_with curl libcurl)
+		$(use_enable curl curlreauthorizationbug)
+		$(use_enable debug)
+		$(use_enable nls)
+		$(use_enable openssl openssl-backend)
+		$(use_enable static-libs static)
+		$(use_enable test)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}