net-libs/libvncserver: bump to vn. 0.9.10_p20160127

Also bump to EAPI 6, full git patch supplied by proxy maintianer via

Gentoo-bug: #563672

Package-Manager: portage-2.2.28

1 files changed, 66 insertions, 0 deletions

diff --git a/net-libs/libvncserver/libvncserver-0.9.10_p20160127.ebuild b/net-libs/libvncserver/libvncserver-0.9.10_p20160127.ebuild
new file mode 100644
index 000000000000..4190a404e2b5
--- /dev/null
+++ b/net-libs/libvncserver/libvncserver-0.9.10_p20160127.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils multilib-minimal vcs-snapshot
+
+DESCRIPTION="library for creating vnc servers"
+HOMEPAGE="http://libvncserver.sourceforge.net/"
+SRC_URI="https://github.com/LibVNC/${PN}/archive/5b322f523faa437d8e7d03736bdb1714e8f84ce5.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="+24bpp gcrypt gnutls ipv6 +jpeg libressl +png ssl static-libs test threads +zlib"
+
+DEPEND="
+	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
+	gnutls? (
+		>=net-libs/gnutls-2.12.23-r6[${MULTILIB_USEDEP}]
+		>=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}]
+	)
+	!gnutls? (
+		ssl? (
+			!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
+			libressl? ( dev-libs/libressl[${MULTILIB_USEDEP}] )
+		)
+	)
+	jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
+	png? ( >=media-libs/libpng-1.6.10:0[${MULTILIB_USEDEP}] )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+src_prepare() {
+	default
+
+	sed -i -r \
+		-e "/^SUBDIRS/s:\<$(usex test '' 'test|')client_examples|examples\>::g" \
+		Makefile.am || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-silent-rules \
+		$(use_enable static-libs static) \
+		$(use_with 24bpp) \
+		$(use_with gnutls) \
+		$(usex gnutls --with-gcrypt $(use_with gcrypt)) \
+		$(usex gnutls --without-ssl $(use_with ssl)) \
+		$(use_with ipv6) \
+		$(use_with jpeg) \
+		$(use_with png) \
+		$(use_with threads pthread) \
+		$(use_with zlib)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}