proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 48 insertions, 0 deletions

diff --git a/net-libs/qxmpp/qxmpp-0.7.6.ebuild b/net-libs/qxmpp/qxmpp-0.7.6.ebuild
new file mode 100644
index 000000000000..9ad8d645387d
--- /dev/null
+++ b/net-libs/qxmpp/qxmpp-0.7.6.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit qt4-r2 multilib
+
+DESCRIPTION="A cross-platform C++ XMPP client library based on the Qt framework"
+HOMEPAGE="http://code.google.com/p/qxmpp/"
+SRC_URI="http://qxmpp.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+IUSE="debug doc test"
+
+RDEPEND="dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	media-libs/speex"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:4 )"
+
+src_prepare(){
+	if ! use doc; then
+		sed -i \
+			-e '/SUBDIRS/s/doc//' \
+			-e '/INSTALLS/d' \
+			qxmpp.pro || die "sed for removing docs failed"
+	fi
+	if ! use test; then
+		sed -i -e '/SUBDIRS/s/tests//' \
+			qxmpp.pro || die "sed for removing tests failed"
+	fi
+	qt4-r2_src_prepare
+}
+
+src_configure(){
+	eqmake4 "${S}"/qxmpp.pro "PREFIX=${EPREFIX}/usr" "LIBDIR=$(get_libdir)"
+}
+
+src_install() {
+	qt4-r2_src_install
+	if use doc; then
+		# Use proper path for documentation
+		mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die "doc mv failed"
+	fi
+}