net-libs/zeromq: Hard depened on sys-libs/libunwind

There is an automatic dependency on sys-libs/libunwind and upstreams issues
a warning if not installed and used anyway.

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/net-libs/zeromq/zeromq-4.2.0-r1.ebuild b/net-libs/zeromq/zeromq-4.2.0-r1.ebuild
new file mode 100644
index 000000000000..7cb9413fb07f
--- /dev/null
+++ b/net-libs/zeromq/zeromq-4.2.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit autotools
+
+DESCRIPTION="A brokerless kernel"
+HOMEPAGE="http://www.zeromq.org/"
+SRC_URI="https://github.com/zeromq/libzmq/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/5"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="pgm +sodium static-libs test"
+
+RDEPEND="
+	sys-libs/libunwind
+	sodium? ( dev-libs/libsodium:= )
+	pgm? ( =net-libs/openpgm-5.2.122 )"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	app-text/xmlto
+	sys-apps/util-linux
+	pgm? ( virtual/pkgconfig )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-dl-backport.patch
+)
+
+src_prepare() {
+	sed \
+		-e '/libzmq_werror=/s:yes:no:g' \
+		-i configure.ac || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_with sodium libsodium)
+		$(use_with pgm)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	# Restricting to one job because multiple tests are using the same port.
+	# Upstream knows the problem and says it doesn't support parallel test
+	# execution, see ${S}/INSTALL.
+	emake -j1 check
+}
+
+src_install() {
+	default
+	find "${ED}"usr/lib* -name '*.la' -delete || die
+}