net-misc/freerdp: new snapshot

Thanks to Ben Kohler for testing.

Bug: https://bugs.gentoo.org/603596
Package-Manager: Portage-2.3.3_p9, Repoman-2.3.1_p2

3 files changed, 120 insertions, 0 deletions

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
index 5d06680883e3..fe8766605262 100644
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -1,2 +1,3 @@
 DIST freerdp-1.2.1_pre20150326.tar.gz 6146857 SHA256 c0646f224ea30a485e165fb31eb8a039af2ca3f257cdf784b319e1b5c13e0425 SHA512 ca1499d56ecb9c9bc624de2ecc976eb9633b795050ac01e16fcc9e0a8951d274cc63644a0e2b830e75f66de894f6a22274864fd20a9351834f6d664874e65ec8 WHIRLPOOL 1ff6ce70d454a7e0cbb3cd4fbafe1fb4191dadc3b2f8a6dbff10d8c725b8fc2838a863837d9b01f6daa670483fe40266fb57569904ad8ac8503549d6605c9e64
 DIST freerdp-2.0.0_pre20160722.tar.gz 6412437 SHA256 17d6b7b9ec6bcfbb78d72ecda034e1ed6bdae4f95a8100297096a5e5e095463a SHA512 3b67de8f31740ccba0ce59f0035328bda6c1602e6197a31008bdd5bcab15e85f473c6c4eca5cb87670b34fa174e4b0da21a7f75be99686df485bb7f9cda6f589 WHIRLPOOL b494070185435da954e9d998915fbe4b47286c803c03bc4839afa583082434fc4d51776b62db27255b9ba62ecb8ef9c95af96e2920414e0fff9b27dceecb4cd4
+DIST freerdp-2.0.0_pre20161219.tar.gz 6425913 SHA256 b71aa5e99624f7bd4c28e69cb2bf3b7710696db121f67091de843c5c652194fd SHA512 ad1699f520df2fdc0719ca35623beaa7b24ca9325e3ed6f30a153a34a237606dc43af2d71068c003f56e4ecbb0bdc07651564d62ba26c792896cecd9065c019a WHIRLPOOL 80dda4d7f97854a19dec48d6169b2cca6bebcd28feab153ca2686faba67d9ae8ae6286661667567315a8e19e7d40bd45c97829171743489681f391236415b8cb
diff --git a/net-misc/freerdp/freerdp-2.0.0_pre20161219.ebuild b/net-misc/freerdp/freerdp-2.0.0_pre20161219.ebuild
new file mode 100644
index 000000000000..1914af228916
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.0.0_pre20161219.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit cmake-utils
+
+if [[ ${PV} != 9999 ]]; then
+	COMMIT=""
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}/FreeRDP-${COMMIT}"
+else
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa +client cpu_flags_x86_sse2 cups debug doc ffmpeg gstreamer jpeg libav libressl neon pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		usb? (
+			virtual/libudev:0=
+			sys-apps/util-linux:0=
+			dev-libs/dbus-glib:0=
+			virtual/libusb:1=
+		)
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg:0 )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+DOCS=( README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_CLIENT=$(usex client)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_DEBUG_ALL=$(usex debug)
+		-DWITH_MANPAGES=$(usex doc)
+		-DWITH_FFMPEG=$(usex ffmpeg)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer)
+		-DWITH_JPEG=$(usex jpeg)
+		-DWITH_NEON=$(usex neon)
+		-DWITH_PULSE=$(usex pulseaudio)
+		-DWITH_SERVER=$(usex server)
+		-DWITH_PCSC=$(usex smartcard)
+		-DWITH_LIBSYSTEMD=$(usex systemd)
+		-DWITH_SSE2=$(usex cpu_flags_x86_sse2)
+		-DCHANNEL_URBDRC=$(usex usb)
+		-DWITH_X11=$(usex X)
+		-DWITH_XINERAMA=$(usex xinerama)
+		-DWITH_XV=$(usex xv)
+		-DBUILD_TESTING=$(usex test)
+		-DWITH_WAYLAND=$(usex wayland)
+	)
+	cmake-utils_src_configure
+}
diff --git a/net-misc/freerdp/freerdp-9999.ebuild b/net-misc/freerdp/freerdp-9999.ebuild
index 78307ff451a8..1914af228916 100644
--- a/net-misc/freerdp/freerdp-9999.ebuild
+++ b/net-misc/freerdp/freerdp-9999.ebuild
@@ -64,6 +64,8 @@ RDEPEND="
 			x11-libs/libXdamage
 			x11-libs/libXext
 			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
 			xinerama? ( x11-libs/libXinerama )
 		)
 	)