net-misc/gnome-remote-desktop: Version bump to 42.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index ac3235876cad..45208c1f2158 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-41.2.tar.xz 111000 BLAKE2B 1d6dfcc9860a5253cfb2a8111c5c039e7d236f45fa79a74ddc479f449b01ddb231368c4b604d28a8f796ab33f1648a332e110fd2adb9b739032dba67c029b9f8 SHA512 7636c0446c86748ce51c869734a2d33d8285c30616a28a0358f45d8399fd9f5dba7a1bdb830d3ca4753982ac3b9715604eb5934906645a1c11c58b4342c524eb
+DIST gnome-remote-desktop-42.0.tar.xz 158448 BLAKE2B 35c5458ec314d7e3abc60583d136e18296609af2caac658cf936685085b6f8b6725bc453336131293dadd1b548d110a4cf5cf8871fcb80d838212e60e204feb1 SHA512 3bf03fc96205df4c5efcef0e340ad85e7011ad8e4fecf2e29d9902fbb1633801da7d1094645e850267249dda9383ae0aa782f3e0207a7351d764482f2d0dc349
diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-42.0.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-42.0.ebuild
new file mode 100644
index 000000000000..e0ed71da320e
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-42.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+inherit gnome.org gnome2-utils meson python-any-r1 systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	>=dev-libs/glib-2.68:2
+	>=media-video/pipewire-0.3.0:=
+	app-crypt/libsecret
+	x11-libs/libnotify
+	media-libs/libepoxy
+	x11-libs/libdrm
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-2.5.0:=[server]
+		>=sys-fs/fuse-3.9.1
+		>=x11-libs/libxkbcommon-1.0.0
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}