net-misc/iodine: revbump wrt security bug #477102

2 files changed, 54 insertions, 1 deletions

diff --git a/net-misc/iodine/iodine-0.7.0-r1.ebuild b/net-misc/iodine/iodine-0.7.0-r1.ebuild
new file mode 100644
index 000000000000..00beaa1c1b4a
--- /dev/null
+++ b/net-misc/iodine/iodine-0.7.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit linux-info eutils toolchain-funcs
+
+DESCRIPTION="IP over DNS tunnel"
+HOMEPAGE="http://code.kryo.se/iodine/"
+SRC_URI="http://code.kryo.se/${PN}/${P}.tar.gz"
+
+CONFIG_CHECK="~TUN"
+
+LICENSE="ISC GPL-2" #GPL-2 for init script bug #426060
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )"
+
+src_prepare(){
+	epatch "${FILESDIR}"/${P}-TestMessage.patch
+	epatch "${FILESDIR}"/${P}-new-systemd.patch
+
+	sed -e '/^\s@echo \(CC\|LD\)/d' \
+		-e 's:^\(\s\)@:\1:' \
+		-i {,src/}Makefile || die
+
+	tc-export CC
+}
+
+src_compile() {
+	#shipped ./Makefiles doesn't pass -j<n> to submake
+	emake -C src TARGETOS=Linux all
+}
+
+src_install() {
+	#don't re-run submake
+	sed -e '/^install:/s: all: :' \
+		-i Makefile || die
+	emake prefix="${EPREFIX}"usr DESTDIR="${D}" install
+
+	dodoc CHANGELOG README TODO
+
+	newinitd "${FILESDIR}"/iodined-1.init iodined
+	newconfd "${FILESDIR}"/iodined.conf iodined
+	keepdir /var/empty
+	fowners root:nogroup /etc/conf.d/iodined
+	fperms 640 /etc/conf.d/iodined
+}
diff --git a/net-misc/iodine/iodine-0.7.0.ebuild b/net-misc/iodine/iodine-0.7.0.ebuild
index ec2d1dd880d0..37870efa450c 100644
--- a/net-misc/iodine/iodine-0.7.0.ebuild
+++ b/net-misc/iodine/iodine-0.7.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$