net-misc/kea: Revbump to add an openrc init script.

Permission kindly granted by Chainsaw.

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 62 insertions, 0 deletions

diff --git a/net-misc/kea/kea-1.2.0-r1.ebuild b/net-misc/kea/kea-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..994aa39c6e42
--- /dev/null
+++ b/net-misc/kea/kea-1.2.0-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs user
+
+MY_PV="${PV//_alpha/a}"
+MY_PV="${MY_PV//_beta/b}"
+MY_PV="${MY_PV//_rc/rc}"
+MY_PV="${MY_PV//_p/-P}"
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="High-performance production grade DHCPv4 & DHCPv6 server"
+HOMEPAGE="http://www.isc.org/kea/"
+SRC_URI="ftp://ftp.isc.org/isc/kea/${MY_P}.tar.gz
+	ftp://ftp.isc.org/isc/kea/${MY_PV}/${MY_P}.tar.gz"
+
+LICENSE="ISC BSD SSLeay GPL-2" # GPL-2 only for init script
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="openssl samples"
+
+DEPEND="
+	dev-libs/boost
+	dev-cpp/gtest
+	dev-libs/log4cplus
+	!openssl? ( dev-libs/botan:= )
+	openssl? ( dev-libs/openssl:= )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Brand the version with Gentoo
+	sed -i \
+		-e "/VERSION=/s:'$: Gentoo-${PR}':" \
+		configure || die
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with openssl)
+		$(use_enable samples install-configurations)
+		--disable-static
+		--without-werror
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	newconfd "${FILESDIR}"/${PN}-confd ${PN}
+	newinitd "${FILESDIR}"/${PN}-initd ${PN}
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}
+
+pkg_preinst() {
+	enewgroup dhcp
+	enewuser dhcp -1 -1 /var/lib/dhcp dhcp
+}