net-misc/nextcloud-client: 3.0.2 bump

Add libressl USE flag, it should work correctly with >=3.1

Closes: https://bugs.gentoo.org/741981
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index e7b73d5b526b..a3ce85aa3474 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,3 +1,4 @@
 DIST nextcloud-client-2.6.5.tar.gz 19134736 BLAKE2B 12defed7dc9a23622d49228c2e78586533f51d1cfd6209e263a0a8b94d307028b1afa76004768432a2bee68140602da003ef10133cd166fd3443a0a45ccccabc SHA512 fcb8ac368e064f9e9ffdc014faabb4f308045d2b047e1011e17bf2e54fa61f462f529eb48e5ec2aa638df8d9720bd7b88acef9b26aa3ba2b90e8977b3be45462
 DIST nextcloud-client-3.0.0.tar.gz 19060293 BLAKE2B 80c53e2db30c9a3a8bae8673a937448915010f9d736836a99660c498c0afe0f3e5d78faf80df4c2214f452c41c9d92357a341f00ecb8f4720f6c459a9d2ccb30 SHA512 5b03ad99feeb16dd7d22399df624da98bf6f2e758337aad5b4ff21f25e39e44d94fe0451101cbc8100e43adbd4a39f8d1bac64881d9e39ef3de58b018ccd35d6
 DIST nextcloud-client-3.0.1.tar.gz 19059671 BLAKE2B c85f9d1627a75745c5a450b1c59799716c17dad3ba5ce277a62bebbbb80f243236cb4d529ff8ce4af9371c7ab1948b5a86dfaa3fbeb9de8681c9df0f397044f7 SHA512 9d6f3d8977f411942703a2dea8990a5b37ef8892b142292720915f5d1937b0443e9cb8c17562eb30a16c31abf30efc023bbb9199079f3a9ca47bdfa51ea5f3a5
+DIST nextcloud-client-3.0.2.tar.gz 19114545 BLAKE2B a6aa041708d110fbdca082476e65ccc8fec189948aa64020a27beabe2d7b3df474ae3313b5aef0e15f3498cf974cf414eb4934417cea206b021e4e212351a088 SHA512 188f878457baba14f01ca6c0f83100bcc64feaf5e3da86903d59d8b7c553c89f88252c1410cd153952950f91429af680b1901f3f9de951bfd06a06c176d44e7d
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.0.2.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.0.2.ebuild
new file mode 100644
index 000000000000..2c3d246de4b1
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.0.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin libressl nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	!libressl? ( >=dev-libs/openssl-1.1.0:0= )
+	libressl? ( >=dev-libs/libressl-3.1:0= )
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}