proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 90 insertions, 0 deletions

diff --git a/net-misc/remmina/remmina-1.2.0_rc3.ebuild b/net-misc/remmina/remmina-1.2.0_rc3.ebuild
new file mode 100644
index 000000000000..fab4fb55573b
--- /dev/null
+++ b/net-misc/remmina/remmina-1.2.0_rc3.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit versionator gnome2-utils cmake-utils
+
+MY_PV_MAIN=$(get_version_component_range 1-3)
+MY_PV_RC=$(get_version_component_range 4)
+MY_PV="${MY_PV_MAIN}-${MY_PV_RC//rc/rcgit.}"
+
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="https://github.com/FreeRDP/Remmina/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 ~x86"
+else
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/Remmina.git
+		https://github.com/FreeRDP/Remmina.git"
+	KEYWORDS=""
+fi
+
+DESCRIPTION="A GTK+ RDP, VNC, XDMCP and SSH client"
+HOMEPAGE="http://freerdp.github.io/Remmina/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="ayatana avahi crypt debug freerdp gnome-keyring nls ssh telepathy vte"
+
+RDEPEND="
+	x11-libs/gtk+:3
+	>=dev-libs/glib-2.31.18:2
+	>=net-libs/libvncserver-0.9.8.2
+	x11-libs/libxkbfile
+	x11-themes/gnome-icon-theme
+	x11-libs/gdk-pixbuf
+	x11-libs/libX11
+	avahi? ( net-dns/avahi[gtk3] )
+	ayatana? ( dev-libs/libappindicator )
+	crypt? ( dev-libs/libgcrypt:0 )
+	freerdp? (
+		>=net-misc/freerdp-1.2
+	)
+	gnome-keyring? ( gnome-base/libgnome-keyring )
+	ssh? ( net-libs/libssh[sftp] )
+	telepathy? ( net-libs/telepathy-glib )
+	vte? ( x11-libs/vte:2.90 )
+"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+RDEPEND+="
+	!net-misc/remmina-plugins
+"
+
+DOCS=( README )
+
+S="${WORKDIR}/Remmina-${MY_PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with ayatana APPINDICATOR)
+		$(cmake-utils_use_with avahi AVAHI)
+		$(cmake-utils_use_with crypt GCRYPT)
+		$(cmake-utils_use_with freerdp FREERDP)
+		$(cmake-utils_use_with gnome-keyring GNOMEKEYRING)
+		$(cmake-utils_use_with nls GETTEXT)
+		$(cmake-utils_use_with nls TRANSLATIONS)
+		$(cmake-utils_use_with ssh LIBSSH)
+		$(cmake-utils_use_with telepathy TELEPATHY)
+		$(cmake-utils_use_with vte VTE)
+		-DGTK_VERSION=3
+	)
+	cmake-utils_src_configure
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}