net-misc/seafile-client: version bump to 7.0.4

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Denis Efremov <efremov@linux.com>
Closes: https://github.com/gentoo/gentoo/pull/13963
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/net-misc/seafile-client/seafile-client-7.0.4.ebuild b/net-misc/seafile-client/seafile-client-7.0.4.ebuild
new file mode 100644
index 000000000000..972e54b95f82
--- /dev/null
+++ b/net-misc/seafile-client/seafile-client-7.0.4.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="Seafile desktop client"
+HOMEPAGE="https://github.com/haiwen/seafile-client/ http://www.seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="shibboleth test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="net-libs/libsearpc
+	~net-misc/seafile-${PV}
+	dev-libs/libevent
+	dev-libs/jansson
+	dev-libs/openssl:0
+	dev-db/sqlite:3
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtdbus:5
+	shibboleth? ( dev-qt/qtwebengine:5[widgets] )"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )"
+BDEPEND="dev-qt/linguist-tools:5"
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-select-qt5.patch"
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHIBBOLETH_SUPPORT="$(usex shibboleth)"
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}