net-misc/tn5250: new revision sans SSLv2/SSLv3 support.

This new revision adds two custom patches. The first drops SSLv2/SSLv3
support by disabling the user's ability to specify "ssl2" or "ssl3" as
his "ssl_method". The fallback "auto" should still work and choose
something secure.

The second patch fixes the build with -Werror=format-security and
consists of trivial format string additions.

Gentoo-Bug: 591940

Package-Manager: portage-2.2.28

1 files changed, 62 insertions, 0 deletions

diff --git a/net-misc/tn5250/tn5250-0.17.4-r2.ebuild b/net-misc/tn5250/tn5250-0.17.4-r2.ebuild
new file mode 100644
index 000000000000..7d7db50c32ac
--- /dev/null
+++ b/net-misc/tn5250/tn5250-0.17.4-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="IBM AS/400 telnet client which emulates 5250 terminals/printers"
+HOMEPAGE="http://tn5250.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="X libressl ssl"
+
+RDEPEND="
+	sys-libs/ncurses:=
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+
+DEPEND="${RDEPEND}
+	X? ( x11-libs/libXt )
+"
+
+PATCHES=(
+	"${FILESDIR}/disable-sslv2-and-sslv3.patch"
+	"${FILESDIR}/fix-Wformat-security-warnings.patch"
+)
+
+src_prepare() {
+	default
+
+	# Next, the Makefile for the terminfo settings tries to remove
+	# some files it doesn't have access to.	 We can just remove those
+	# lines.
+	sed -i \
+		-e "/rm -f \/usr\/.*\/terminfo.*5250/d" linux/Makefile.in \
+		|| die "sed Makefile.in failed"
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--without-python \
+		$(use_with X x) \
+		$(use_with ssl)
+}
+
+src_install() {
+	# The TERMINFO variable needs to be defined for the install
+	# to work, because the install calls "tic."	 man tic for
+	# details.
+	dodir /usr/share/terminfo
+	emake DESTDIR="${D}" TERMINFO="${D}/usr/share/terminfo" install
+
+	einstalldocs
+	prune_libtool_files
+}