net-misc/trackma: bump to 0.8.2

Also eliminate optional dep on py2-only inotifyx

Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 62 insertions, 0 deletions

diff --git a/net-misc/trackma/Manifest b/net-misc/trackma/Manifest
index 20f2a7b75660..b4953e07ac78 100644
--- a/net-misc/trackma/Manifest
+++ b/net-misc/trackma/Manifest
@@ -1 +1,2 @@
 DIST trackma-0.7.4.tar.gz 143814 BLAKE2B 8fafa53b4af94a1078e2343b1b309efe8caa058809309ddbdae618b2b3d85fbf001cb73c2556fd50b8946c9d61ddb32d74c3bb5be9bb2c2501b29265a587e2d4 SHA512 88b7eacc6a60fec5b022787337274b95d0fb972dbdd8ffa1a000806612403d8f84a2317e5903ec1ffcdbac91132a960670855991c0885f526fdbc4a1033c3364
+DIST trackma-0.8.2.tar.gz 171917 BLAKE2B 9fedd04036d55ef8fa748e64a18a2d471cab61b71030840baf18252cb81d2ad3df72eba6d417484c2772cb81d3e0e6e2311440c77040a899152681e427408a7a SHA512 6063f65fa70ee65f3b30cd2750bc1f501a6a94dc796195f11d89f4430cdae830fc5987bf6d261c77603c9cc5d32f80286aeecc05d44f766ca705e932997d46f1
diff --git a/net-misc/trackma/trackma-0.8.2.ebuild b/net-misc/trackma/trackma-0.8.2.ebuild
new file mode 100644
index 000000000000..fc1e2899065b
--- /dev/null
+++ b/net-misc/trackma/trackma-0.8.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{3_5,3_6} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Open multi-site list manager for media tracking sites"
+HOMEPAGE="https://github.com/z411/trackma"
+SRC_URI="https://github.com/z411/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+ncurses cli gtk inotify qt5"
+REQUIRED_USE="|| ( cli gtk ncurses qt5 )"
+
+DEPEND="ncurses? ( dev-python/urwid[${PYTHON_USEDEP}] )
+	gtk? (
+		dev-python/pygobject:3[${PYTHON_USEDEP},cairo]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)
+	qt5? (
+		dev-python/PyQt5[${PYTHON_USEDEP},gui,widgets]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)"
+RDEPEND="sys-process/lsof
+	inotify? ( dev-python/pyinotify )
+	${DEPEND}"
+
+python_configure_all() {
+	sed -i -e '/trackma-qt4/d' "${S}/setup.py" || die
+	rm "${S}/trackma/ui/qt/qt4ui.py" || die
+	if ! use qt5; then
+		sed -i -e '/trackma-qt/d' "${S}/setup.py" || die
+		rm -r "${S}/trackma/ui/qt" || die
+	fi
+	if ! use gtk; then
+		sed -i -e '/trackma-gtk/d' "${S}/setup.py" || die
+		rm -r "${S}/trackma/ui/gtk" || die
+	fi
+	if ! use ncurses; then
+		sed -i -e '/trackma-curses/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/curses.py" || die
+	fi
+	if ! use cli; then
+		sed -i -e '/trackma.ui.cli:main/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/cli.py" || die
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	newicon "${S}/trackma/data/icon.png" trackma.png
+	use cli && make_desktop_entry "${PN}" "${PN^} (cli)" "${PN}" "Network" "Terminal=true"
+	use ncurses && make_desktop_entry "${PN}-curses" "${PN^} (ncurses)" "${PN}" "Network" "Terminal=true"
+	use gtk && make_desktop_entry "${PN}-gtk" "${PN^} (gtk3)" "${PN}" "Network" "StartupWMClass=trackma-gtk3"
+	use qt5 && make_desktop_entry "${PN}-qt" "${PN^} (qt5)" "${PN}" "Network" "StartupWMClass=trackma-qt5"
+}