net-misc/youtube-dl: Version 2020.03.08

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index af411d85d719..92ef9fafe724 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1,3 +1,4 @@
 DIST youtube-dl-2020.02.16.tar.gz 3161956 BLAKE2B 36cd189b162d98f986d669c4439070efbf344aa05f821b9e35a58fcef8db839ad0e079836e7a84cd17b04afdb113559695ad500f4b0183c7dcefa1694bdccf62 SHA512 1164ad9f875d67844ddc7bf8214bcc06cb384d7f2a5661c1f419f2ce5950b1cfcbf90c558e143b76948d9d7cf57cf3843c8d6392fc6ef77f89319375610f01a2
 DIST youtube-dl-2020.03.01.tar.gz 3163319 BLAKE2B 27ca596ef09b0506974059b9bdbb63feb15be772ac6aadbfc36d8abc24d736a3eef37e327a3bb6e16672da19d88626f7f84f61d21cabe18f7d17998f362094d9 SHA512 2a48bdf05d0cb918f643af3a5a7c2e675bda4315220079c90c21acf284a1ceb03fabcb0698c4b1e8740b826cbb5598a87a6563d6b96f129d274854bfdd5ecdf3
 DIST youtube-dl-2020.03.06.tar.gz 3164364 BLAKE2B 8a714662520a6ca84d3a1643c2484f46fc33b2c5d345fecae5bcc4d7c9a297ac6e4a7a1488fff2db3c5719017d242ecf6ba41ba2c5c1aeb781e6ae8be85d96fe SHA512 364e5955b233e7b5870b18f7e3eb3ec128cafd70feb86384aace36a42f85e793d2eb8f9e940cb7a45854d0cca2886f75f913c461dd27520f4cd023e0ff979d1e
+DIST youtube-dl-2020.03.08.tar.gz 3164037 BLAKE2B 1f011657f394d101106fbed32e13e8bac18199db742974fb43b121b2c76324612f62a8e4a7324e4361643b62a5ad9a1937cc068bf3ea949f9411b92563a61bc9 SHA512 09636e3ec526dbcb043cf61ed4dda5c5c00fac2ecd741bf3cb338ca8de72d1395a95a6189bccced140ca1c37eb3f693332e757ff01eb1a25279b100ccdf39b65
diff --git a/net-misc/youtube-dl/youtube-dl-2020.03.08.ebuild b/net-misc/youtube-dl/youtube-dl-2020.03.08.ebuild
new file mode 100644
index 000000000000..cc4f38a726e5
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.03.08.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python3_{6,7,8})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}