net-misc/youtube-dl: Version 2019.05.20

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 670c0d65feda..615792619c02 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2019.05.11.tar.gz 3167002 BLAKE2B aad84dcb9f729bd3c6622978c2f9d2d1d9b20c6a7bc59a9d134cff4a857abcb6e5360f058399f5385a5f088f0a695077786a56b94f68fce4e4518bf090b762a1 SHA512 e47a2163d73554fc125a2ac9c14cb12eadd506f6416fd673d687e9a068ece34e95d7f59483aefaa329da0a8c4b72e6d1debc2a8d3bd6c7ded5fbe543c5d769b9
+DIST youtube-dl-2019.05.20.tar.gz 3167834 BLAKE2B fe5501380b5134665b3c5c31a7b703832d7c7d9675c1e7c20bfa2b4ebc175e37521b423b68d3701a3637e047e3d4f12e54786f7d6f23e896f0a9da93c39be6f5 SHA512 c50661585f987a6c2abc7b9940749a2ba8e9a534d66f0846dddb265be3fe5a58ba8009fbad44c2551c7574b73bc21aa35f7d633729c0090c46e5818199dccb1d
diff --git a/net-misc/youtube-dl/youtube-dl-2019.05.20.ebuild b/net-misc/youtube-dl/youtube-dl-2019.05.20.ebuild
new file mode 100644
index 000000000000..a8b1afbfc11a
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.05.20.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_5,3_6,3_7})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://rg3.github.com/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+RESTRICT="test"
+SLOT="0"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}