net-p2p/ktorrent: 21.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/net-p2p/ktorrent/Manifest b/net-p2p/ktorrent/Manifest
index 662206cdb754..d983cf0bb0c4 100644
--- a/net-p2p/ktorrent/Manifest
+++ b/net-p2p/ktorrent/Manifest
@@ -1 +1,2 @@
 DIST ktorrent-21.08.3.tar.xz 2091880 BLAKE2B aa0c28313d86fec1e472582dbf68023a71cee5c9fa301e243c3e4bc2e25987fcee28b34f21264b253eb1eaac955e4d2f994e5936f75bb6182fdb648617382ff0 SHA512 10ebe41f9ef85d1b6ad927e197193fff5d776947e4a8c4a5d3498d16304372b4ca8afd993a94d783934b89139a375ab86dc4893b1c7eaae2b4f70f02fc36ab5c
+DIST ktorrent-21.12.0.tar.xz 2064536 BLAKE2B fbc722621e7abe7926a55c19146b4df4c7ed07db2bf894bd2ac7741692cc5d663f5752fa594a0b0e301197f5dbbdbf641214314d15fec45271edc64ca941bec6 SHA512 3c4bb87552c9247092c21a692dcd851ac2ae8da2e9c4e407db198876c7aaceffa44d56cb89499788d3b07727fbb8797961bff0bc287900ce05a2f5a28f0c2b93
diff --git a/net-p2p/ktorrent/ktorrent-21.12.0.ebuild b/net-p2p/ktorrent/ktorrent-21.12.0.ebuild
new file mode 100644
index 000000000000..420415c1390d
--- /dev/null
+++ b/net-p2p/ktorrent/ktorrent-21.12.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="optional"
+KDE_GEAR="true"
+KFMIN=5.88.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +logviewer +magnetgenerator
++mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=net-libs/libktorrent-${PVCUT}:5
+	infowidget? ( dev-libs/geoip )
+	mediaplayer? (
+		>=media-libs/phonon-4.11.0
+		>=media-libs/taglib-1.5
+	)
+	rss? (
+		>=dev-qt/qtwebengine-${QTMIN}:5
+		>=kde-frameworks/syndication-${KFMIN}:5
+	)
+	shutdown? ( kde-plasma/libkworkspace:5 )
+	stats? ( >=kde-frameworks/kplotting-${KFMIN}:5 )
+	upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+	zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	ipfilter? (
+		app-arch/bzip2
+		app-arch/unzip
+		kde-apps/kio-extras:5
+		>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	)
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
+		-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
+		-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
+		-DWITH_SYSTEM_GEOIP=$(usex infowidget)
+		-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
+		-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
+		-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
+		-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
+		$(cmake_use_find_package rss KF5Syndication)
+		-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
+		-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
+		-DENABLE_STATS_PLUGIN=$(usex stats)
+		-DENABLE_UPNP_PLUGIN=$(usex upnp)
+		-DENABLE_SEARCH_PLUGIN=$(usex webengine)
+		-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
+	)
+# add back when ported
+# 		-DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
+	ecm_src_configure
+}