net-wireless/blueman: Bump to 2.3.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 154 insertions, 13 deletions

diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index eadb14121b05..d3c683a6996a 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1,2 +1,3 @@
 DIST blueman-2.2.3.tar.xz 1587268 BLAKE2B b3a2d275904959437a47eec32b16f9ebd945bf49705d4f4752d9bfa40d7764b73d373225875773491432cf5b72319eba51a7206cccf10dcf6033a98f584a0504 SHA512 ccaf624bdea116c70b375ae62c1b477452207e8df0fa0941b0e80ac9fa9fbf760fa0bd0db1e7dc1e63f6010323c4b0bb228e315a0cb8f6a4283cd9da6cfa012b
 DIST blueman-2.2.5.tar.xz 1575260 BLAKE2B 9e26b3406114b1dd3257bcfd0850bf16385ac3eb2fcd89097e3a0464099b7c64eb4cf1f5cd7630a8387fd258b4b0bf8bc52f01c5da480e543bd11346995392c2 SHA512 265a9286ac943a41f78b587a93e8759ca87b49fcda5a7b34ce520d9e0aee8e6335a1219f46d1c3d9bd3f07be15913b5c4bc101daaa5e9e5b380703733c021a35
+DIST blueman-2.3.1.tar.xz 1606200 BLAKE2B 6f4528e827824884c763da81aff9642e442c3b8e465f9c2dfae9e63de409956e946ba3f939a64ae68f0d05df11e49927daab2af189e8605ccc5e4897ca8fb7ab SHA512 04adbb3eff4571cf105cad2769d7ad8e4055112a7e1b3c1152b300e72534621647cc6a0f284915cc2d3c642b8c1acf825c8c9a0227dbb617fa9071a534f0562c
diff --git a/net-wireless/blueman/blueman-2.3.1.ebuild b/net-wireless/blueman/blueman-2.3.1.ebuild
new file mode 100644
index 000000000000..dbedcfc7eae6
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.3.1.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit autotools distutils-r1 gnome2-utils linux-info systemd xdg-utils
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman/"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
+else
+	SRC_URI="
+		https://github.com/blueman-project/blueman/releases/download/${PV/_/.}/${P/_/.}.tar.xz
+	"
+	S=${WORKDIR}/${P/_/.}
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+# icons are GPL-2
+# source files are mixed GPL-3+ and GPL-2+
+LICENSE="GPL-3+ GPL-2"
+SLOT="0"
+IUSE="network nls policykit pulseaudio"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	>=net-wireless/bluez-5:=
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/cython[${PYTHON_USEDEP}]
+	')
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	')
+	sys-apps/dbus
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+	|| (
+		x11-themes/adwaita-icon-theme
+		x11-themes/faenza-icon-theme
+		x11-themes/mate-icon-theme
+	)
+	network? (
+		net-firewall/iptables
+		|| (
+			sys-apps/net-tools
+			sys-apps/iproute2
+		)
+		|| (
+			net-dns/dnsmasq
+			net-misc/dhcp
+			>=net-misc/networkmanager-0.8
+		)
+	)
+	policykit? (
+		sys-auth/polkit
+	)
+	pulseaudio? (
+		|| (
+			media-sound/pulseaudio-daemon[bluetooth]
+			media-video/pipewire[bluetooth]
+			<media-sound/pulseaudio-15.99.1[bluetooth]
+			media-sound/pulseaudio-modules-bt
+		)
+	)
+"
+
+pkg_pretend() {
+	if use network; then
+		local CONFIG_CHECK="
+			~BRIDGE
+			~IP_NF_IPTABLES
+			~IP_NF_NAT
+			~IP_NF_TARGET_MASQUERADE
+		"
+		check_extra_config
+	fi
+}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	[[ ${PV} == 9999 ]] && eautoreconf
+	distutils-r1_src_prepare
+}
+
+python_configure() {
+	local myconf=(
+		--disable-runtime-deps-check
+		--disable-static
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+		--with-systemduserunitdir="$(systemd_get_userunitdir)"
+		--with-dhcp-config="/etc/dhcp/dhcpd.conf"
+		$(use_enable policykit polkit)
+		$(use_enable nls)
+		$(use_enable pulseaudio)
+		# thunar integration is a single data file with no extra deps
+		# so install it unconditionally
+		--enable-thunar-sendto
+	)
+	econf "${myconf[@]}"
+}
+
+python_install() {
+	default
+
+	if use policykit; then
+		# Allow users in plugdev group to modify connections
+		insinto /usr/share/polkit-1/rules.d
+		doins "${FILESDIR}/01-org.blueman.rules"
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
diff --git a/net-wireless/blueman/blueman-9999.ebuild b/net-wireless/blueman/blueman-9999.ebuild
index 14d5a18e335a..dbedcfc7eae6 100644
--- a/net-wireless/blueman/blueman-9999.ebuild
+++ b/net-wireless/blueman/blueman-9999.ebuild
@@ -3,9 +3,11 @@
 
 EAPI=8
 
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=no
 PYTHON_COMPAT=( python3_{8..11} )
 
-inherit autotools gnome2-utils linux-info python-single-r1 systemd xdg-utils
+inherit autotools distutils-r1 gnome2-utils linux-info systemd xdg-utils
 
 DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
 HOMEPAGE="https://github.com/blueman-project/blueman/"
@@ -25,22 +27,23 @@ fi
 # source files are mixed GPL-3+ and GPL-2+
 LICENSE="GPL-3+ GPL-2"
 SLOT="0"
-IUSE="appindicator network nls policykit pulseaudio"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+IUSE="network nls policykit pulseaudio"
 
 DEPEND="
 	$(python_gen_cond_dep '
 		dev-python/pygobject:3[${PYTHON_USEDEP}]
 	')
 	>=net-wireless/bluez-5:=
-	${PYTHON_DEPS}"
+"
 BDEPEND="
 	$(python_gen_cond_dep '
 		dev-python/cython[${PYTHON_USEDEP}]
 	')
 	virtual/pkgconfig
-	nls? ( sys-devel/gettext )"
-RDEPEND="${DEPEND}
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="
+	${DEPEND}
 	$(python_gen_cond_dep '
 		dev-python/pycairo[${PYTHON_USEDEP}]
 	')
@@ -52,9 +55,6 @@ RDEPEND="${DEPEND}
 		x11-themes/faenza-icon-theme
 		x11-themes/mate-icon-theme
 	)
-	appindicator? (
-		dev-libs/libappindicator:3[introspection]
-	)
 	network? (
 		net-firewall/iptables
 		|| (
@@ -97,18 +97,17 @@ pkg_setup() {
 }
 
 src_prepare() {
-	default
 	[[ ${PV} == 9999 ]] && eautoreconf
+	distutils-r1_src_prepare
 }
 
-src_configure() {
+python_configure() {
 	local myconf=(
 		--disable-runtime-deps-check
 		--disable-static
 		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
 		--with-systemduserunitdir="$(systemd_get_userunitdir)"
 		--with-dhcp-config="/etc/dhcp/dhcpd.conf"
-		$(use_enable appindicator)
 		$(use_enable policykit polkit)
 		$(use_enable nls)
 		$(use_enable pulseaudio)
@@ -119,7 +118,7 @@ src_configure() {
 	econf "${myconf[@]}"
 }
 
-src_install() {
+python_install() {
 	default
 
 	if use policykit; then