proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/sci-libs/libccd/libccd-2.0.ebuild b/sci-libs/libccd/libccd-2.0.ebuild
new file mode 100644
index 000000000000..6d67b3690c78
--- /dev/null
+++ b/sci-libs/libccd/libccd-2.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="http://github.com/danfis/libccd"
+fi
+
+inherit ${SCM} cmake-utils toolchain-funcs
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~arm"
+	SRC_URI="http://libccd.danfis.cz/files/${P}.tar.gz"
+fi
+
+DESCRIPTION="Library for collision detection between two convex shapes"
+HOMEPAGE="http://libccd.danfis.cz/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="double doc"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx )"
+DOCS=( README )
+
+src_configure() {
+	local mycmakeargs=(
+		"-DCCD_DOUBLE=$(usex double TRUE FALSE)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	if use doc ; then
+		cd "${S}/doc"
+		emake SPHINXBUILD=sphinx-build html
+	fi
+}
+
+src_test() {
+	cd src/testsuites
+	tc-export CC
+	LDFLAGS="-L${BUILD_DIR} ${LDFLAGS}" \
+	LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" \
+		emake check
+}
+
+src_install() {
+	cmake-utils_src_install
+	use doc && dohtml -r "${S}/doc/_build/html/"*
+}