sys-apps/fwupd: Bump to version 1.5.6

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

4 files changed, 216 insertions, 0 deletions

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 567e274eee7a..f2308e9a897d 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,3 +1,4 @@
 DIST fwupd-1.4.6.tar.gz 2368201 BLAKE2B 86f4e8a3264b69eb72a357f59db082e81534dc28822934df328b1bf94aacb7ed1a219f8e5a03a9a37a0d07c248410822a3d12c4fd6b5df3a14157795e092a095 SHA512 c456704f40e7c5a5225255dbe3e4b794819d3fa982683a31b15a81f5467f007eef00cd80dac1844eca00ebab9ae12061139ae31c1fd7e2a6e012779d2a4b59f9
 DIST fwupd-1.5.4.tar.gz 2435897 BLAKE2B 23318f5305e3f2478c866e17e150ca3863e5eebf922e81f28a35541af4d9786dada8d2084e51b51e97343bdbf132e9b9981b8bb321ad4e76fba8c42b8b1e2e64 SHA512 961c9298e7672f720f4b6865d374b6066379f0a1c1a99356a9efd9359ee737cf9f9ab2c708f81505c971484d172b8dae96bc5f06be6e6f13c4a55604e6c346e7
 DIST fwupd-1.5.5.tar.gz 2460482 BLAKE2B 79d1b34c07a0befe355e9a6c68770dfbbc575fd540802dd20ae4f65061d9fffd6245944e6f33b702539a5e88563afc7b4c619ca1507e31465dcf40138f92902f SHA512 a37f16b01e6700b0302293a916a379a89b574eed13f63577c19fa8b0ec396bd19f7f7d5c708085f3817af60fca65c02b0ddc4370de82104a5e8e65f583ff3f4a
+DIST fwupd-1.5.6.tar.gz 2480802 BLAKE2B ab9d9cffaf74b4ce6a9de47ef37aa05efae0c0b353f879eb3d0573fd4153c0893922c3a47b68188998752c2f9a75ca340ecb7af94e6c85890060f3826900f812 SHA512 6a04151b53c4446c15527f6b1396ba238b749c6f767dff4171849ccbdab8db2619fd1e3f0e146fd67681263621d55f20008709c7bac10a6d34f27f06c7118cfe
diff --git a/sys-apps/fwupd/files/fwupd-1.5.6-gusb_deps.patch b/sys-apps/fwupd/files/fwupd-1.5.6-gusb_deps.patch
new file mode 100644
index 000000000000..00c79d7853b8
--- /dev/null
+++ b/sys-apps/fwupd/files/fwupd-1.5.6-gusb_deps.patch
@@ -0,0 +1,44 @@
+From c74992c62a32080208baf137d61f7d73b0cade2d Mon Sep 17 00:00:00 2001
+From: Lars Wendler <polynomial-c@gentoo.org>
+Date: Tue, 16 Feb 2021 16:57:36 +0100
+Subject: [PATCH] system76-launch plugin requires gusb
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+Otherwise the following build error happens:
+
+  ../fwupd-1.5.6/plugins/system76-launch/fu-system76-launch-device.c:117:9: error: ‘G_USB_DEVICE_CLAIM_INTERFACE_BIND_KERNEL_DRIVER’ undeclared (first use in this function)
+    117 |         G_USB_DEVICE_CLAIM_INTERFACE_BIND_KERNEL_DRIVER,
+        |         ^~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
+
+  ../fwupd-1.5.6/plugins/system76-launch/fu-system76-launch-device.c:133:11: error: ‘G_USB_DEVICE_CLAIM_INTERFACE_BIND_KERNEL_DRIVER’ undeclared (first use in this function)
+    133 |           G_USB_DEVICE_CLAIM_INTERFACE_BIND_KERNEL_DRIVER,
+        |           ^~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
+---
+ plugins/meson.build | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/plugins/meson.build b/plugins/meson.build
+index 138c47a4..12c7cb31 100644
+--- a/plugins/meson.build
++++ b/plugins/meson.build
+@@ -25,7 +25,6 @@ subdir('ata')
+ subdir('elantp')
+ subdir('optionrom')
+ subdir('superio')
+-subdir('system76-launch')
+ subdir('thelio-io')
+ subdir('wacom-raw')
+ endif
+@@ -59,6 +58,7 @@ subdir('solokey')
+ subdir('steelseries')
+ subdir('synaptics-cxaudio')
+ subdir('synaptics-prometheus')
++subdir('system76-launch')
+ subdir('vli')
+ subdir('wacom-usb')
+ 
+-- 
+2.30.1
+
diff --git a/sys-apps/fwupd/fwupd-1.5.6.ebuild b/sys-apps/fwupd/fwupd-1.5.6.ebuild
new file mode 100644
index 000000000000..891236d11e11
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.5.6.ebuild
@@ -0,0 +1,169 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="agent amt archive dell gnutls gtk-doc gusb elogind flashrom minimal introspection +man nvme policykit synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	dell? ( uefi )
+	minimal? ( !introspection )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+	man? (
+		app-text/docbook-sgml-utils
+		sys-apps/help2man
+	)
+	test? (
+		thunderbolt? ( dev-util/umockdev )
+		net-libs/gnutls[tools]
+	)
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libjcat-0.1.0[gpg,pkcs7]
+	>=dev-libs/libxmlb-0.1.13:=
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+	')
+	>=net-libs/libsoup-2.51.92:2.4[introspection?]
+	net-misc/curl
+	virtual/libelf:0=
+	virtual/udev
+	archive? ( app-arch/libarchive:= )
+	dell? ( >=sys-libs/libsmbios-2.4.0 )
+	elogind? ( >=sys-auth/elogind-211 )
+	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+	gnutls? ( net-libs/gnutls )
+	gusb? ( >=dev-libs/libgusb-0.3.5[introspection?] )
+	policykit? ( >=sys-auth/polkit-0.103 )
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss )
+	uefi? (
+		media-libs/fontconfig
+		media-libs/freetype
+		sys-boot/gnu-efi
+		sys-boot/efibootmgr
+		sys-fs/udisks
+		sys-libs/efivar
+		x11-libs/cairo
+	)
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+	!<sci-chemistry/chemical-mime-data-0.1.94-r4
+	${COMMON_DEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/pango[introspection]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3.9-logind_plugin.patch"
+	"${FILESDIR}/${PN}-1.5.6-gusb_deps.patch"
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	if use nvme ; then
+		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+	fi
+}
+
+src_prepare() {
+	default
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+	sed '/platform-integrity/d' \
+		-i plugins/meson.build || die #753521
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		$(meson_use agent)
+		$(meson_use amt plugin_amt)
+		$(meson_use archive libarchive)
+		$(meson_use dell plugin_dell)
+		$(meson_use elogind)
+		$(meson_use flashrom plugin_flashrom)
+		$(meson_use gnutls)
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use gusb)
+		$(meson_use gusb plugin_altos)
+		$(meson_use man)
+		$(meson_use nvme plugin_nvme)
+		$(meson_use introspection)
+		$(meson_use policykit polkit)
+		$(meson_use synaptics plugin_synaptics_mst)
+		$(meson_use synaptics plugin_synaptics_rmi)
+		$(meson_use systemd)
+		$(meson_use test tests)
+		$(meson_use thunderbolt plugin_thunderbolt)
+		$(meson_use tpm)
+		$(meson_use uefi plugin_uefi_capsule)
+		$(meson_use uefi plugin_uefi_pk)
+		-Dconsolekit="false"
+		-Dcurl="true"
+		# Dependencies are not available (yet?)
+		-Dplugin_modem_manager="false"
+	)
+	use ppc64 && emesonargs+=( -Dplugin_msr="false" )
+	use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		sed "s@%SEAT_MANAGER%@elogind@" \
+			"${FILESDIR}"/${PN}-r1 \
+			> "${T}"/${PN} || die
+		doinitd "${T}"/${PN}
+
+		if ! use systemd ; then
+			# Don't timeout when fwupd is running (#673140)
+			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+				-i "${ED}"/etc/${PN}/daemon.conf || die
+		fi
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "In case you are using openrc as init system"
+	elog "and you're upgrading from <fwupd-1.1.0, you"
+	elog "need to start the fwupd daemon via the openrc"
+	elog "init script that comes with this package."
+}
diff --git a/sys-apps/fwupd/metadata.xml b/sys-apps/fwupd/metadata.xml
index c4fce7423fee..b2692d9a2fc8 100644
--- a/sys-apps/fwupd/metadata.xml
+++ b/sys-apps/fwupd/metadata.xml
@@ -7,9 +7,11 @@
   </maintainer>
   <use>
     <flag name="agent">Enable update notification agent</flag>
+    <flag name="archive">Use <pkg>app-arch/libarchive</pkg> for archives support</flag>
     <flag name="amt">Build and install Intel AMT plugin</flag>
     <flag name="dell">Enable Dell-specific support.</flag>
     <flag name="flashrom">Enable flashrom plugin via <pkg>sys-apps/flashrom</pkg></flag>
+    <flag name="gusb">Enable <pkg>dev-libs/libgusb</pkg> support</flag>
     <flag name="man">Build and install man pages</flag>
     <flag name="nvme">Build and install NVMe plugin</flag>
     <flag name="redfish">Install redfish plugin</flag>