sys-block/gparted: Version bump to 1.3.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/sys-block/gparted/Manifest b/sys-block/gparted/Manifest
index b5cea111fd64..3424f0fbd220 100644
--- a/sys-block/gparted/Manifest
+++ b/sys-block/gparted/Manifest
@@ -1 +1,2 @@
 DIST gparted-1.3.0.tar.gz 4167440 BLAKE2B 87af5285a54af2ceb75eb6580b6492f7bcf6d8d2a9b4d614761b60c2b1776b2a8e14064ed5a77091074c5c5ff87169f3525fec2f37a280d35289677aaf75eba5 SHA512 8349ebdf2312e32df9f40d24aa42a4604897ebae72e58fd1046ab0897b3380a762b49f74bdcf3bd570b4e7a3468b6f225c22290c6b1b799911da17408912288b
+DIST gparted-1.3.1.tar.gz 4169647 BLAKE2B 0e79ea51df79460ae70e15a0f4d5bb1158dd808b52224bdf78f153bada278e6a8cb1606aa99e564016db0b4755e4063e0db151628d8d03904626e9f5648d61a1 SHA512 2dd2b1eae72f627d8f302d34286e684c6b884faf0246f1f534795213d243a9416ff2a7ead48f44958de1ce00248550336176c0df2469ede825b22ed1b5915c76
diff --git a/sys-block/gparted/gparted-1.3.1.ebuild b/sys-block/gparted/gparted-1.3.1.ebuild
new file mode 100644
index 000000000000..919eed8b3de0
--- /dev/null
+++ b/sys-block/gparted/gparted-1.3.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2 optfeature virtualx
+
+DESCRIPTION="Partition editor for graphically managing your disk partitions"
+HOMEPAGE="https://gparted.org/ https://gitlab.gnome.org/GNOME/gparted/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+ FDL-1.2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="kde policykit wayland"
+
+DEPEND="
+	!policykit? (
+		kde? ( >=kde-plasma/kde-cli-tools-5.8.6-r1[kdesu] ) )
+	policykit? ( >=sys-auth/polkit-0.102 )
+	>=dev-cpp/glibmm-2.56.1:2
+	>=dev-cpp/gtkmm-3.24:3.0
+	>=dev-libs/glib-2.58.3-r1:2
+	>=sys-block/parted-3.2:=
+	>=dev-libs/libsigc++-2.10.1:2
+"
+RDEPEND="${DEPEND}
+	>=sys-apps/util-linux-2.33.2
+	wayland? ( x11-apps/xhost )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	>=dev-util/intltool-0.51.0-r2
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-doc \
+		--enable-online-resize \
+		$(use_enable wayland xhost-root) \
+		GKSUPROG=kdesu \
+		ac_cv_prog_have_scrollkeeper_update=no
+}
+
+src_install() {
+	gnome2_src_install
+
+	local _ddir="${D}"/usr/share/applications
+	local _bdir="${D}"/usr/bin
+
+	if ! use policykit; then
+		if use kde; then
+			cp "${_ddir}"/gparted{,-kde}.desktop || die
+			cp "${_bdir}"/gparted{,-kde} || die
+			sed -i -e '/Exec/ s:gparted:gparted-kde:' "${_ddir}"/gparted-kde.desktop || die
+			echo 'OnlyShowIn=KDE;' >> "${_ddir}"/gparted-kde.desktop || die
+		fi
+	else
+		sed -i -e 's:kdesu::' "${_bdir}"/gparted || die
+	fi
+
+	mv "${ED}"/usr/share/{appdata,metainfo}
+}
+
+src_test() {
+	virtx emake check
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	optfeature_header
+	optfeature "BTRFS support"                   sys-fs/btrfs-progs
+	optfeature "DMRAID support"                  sys-fs/dmraid sys-fs/multipath-tools
+	optfeature "Encrypted device / LUKS support" sys-fs/cryptsetup
+	optfeature "exFAT support"                   sys-fs/exfatprogs
+	optfeature "EXT2/EXT3/EXT4 support"          sys-fs/e2fsprogs
+	optfeature "F2FS support"                    sys-fs/f2fs-tools
+	optfeature "FAT support"                     sys-fs/dosfstools sys-fs/mtools
+	optfeature "HFS support"                     sys-fs/diskdev_cmds sys-fs/hfsutils virtual/udev
+	optfeature "JFS support"                     sys-fs/jfsutils
+	optfeature "MDADM support"                   sys-fs/mdadm
+	optfeature "NTFS support"                    sys-fs/ntfs3g[ntfsprogs]
+	optfeature "Reiser4 support"                 sys-fs/reiser4progs
+	optfeature "ReiserFS support"                sys-fs/reiserfsprogs
+	optfeature "UDF support"                     sys-fs/udftools
+	optfeature "XFS support"                     sys-fs/xfsprogs sys-fs/xfsdump
+}