sys-cluster/cinder: MITAKA release

Package-Manager: portage-2.2.26

2 files changed, 176 insertions, 0 deletions

diff --git a/sys-cluster/cinder/Manifest b/sys-cluster/cinder/Manifest
index 6c3b056a8e4a..52a1e64f80c0 100644
--- a/sys-cluster/cinder/Manifest
+++ b/sys-cluster/cinder/Manifest
@@ -1,4 +1,5 @@
 DIST cinder-7.0.1.tar.gz 2599206 SHA256 e02c37efdff0e1792f2a621b2dbb260e66db7c61fc0bba8cc1dd428e09eb05dc SHA512 1b32b96624f05e23b1ca78136ed2a8854df0da474912a2bcdda28395f233115271ae9f9f2e4eafa2efa97b2c9ae9143413bf60e13dc3c4f6251a6ba08e95daa0 WHIRLPOOL 92d9345ae81751c71b74964b6e8cbd33fc797cd8b9c449651449cd878a335811e4895ca3e1cd23d0f28d8bec68d23b6a199a6c2a21510d5858cfbe3f971d1444
+DIST cinder-8.0.0.tar.gz 3955244 SHA256 bd05f3c0b7b2ae098284c062d20230aecdaa47ed623cb79907c39dd1e28f8a2e SHA512 5c6ec1dc172036068016373e2d30e55c88f07dae12438fcfe207caea2965360f0c7df5aff1a901c6e2442ebf0dbd56f0428e3f24651f6cdd682bb659f636b20c WHIRLPOOL 3bcd4477b7fd65b45dc305198fa8462e5c3bfffbdf75170607facdb446308aa9301a609090b4b43968369bf737b851d73a31af9b63752522b960850b3b6c0845
 DIST liberty-cinder.conf.sample 122223 SHA256 dad765cbe995576c23b4aa45e316272826fd9a293bf111bcdcb2da9ab562fb43 SHA512 64696a606233fa6a0f2c844924a61e48552f38ce54dadbc8202455d32b9fa37575c8e1d5c1b3e086d37f832e60f754007f2bfa9cd4915e3ae5fd52e283896f64 WHIRLPOOL 2d03754cfe60be0b0f278181e3b9cec399227e643032d9bb53fdafb4504793da6459ceb9b93802d5452ab9b77d9b613ff87f04605833553011a0847d9d3f7e2c
 DIST mitaka-cinder-api-paste.ini 2416 SHA256 3794a5e34dace60474274e93a7346662eb03a485d1b9b67afded591e764aba9d SHA512 f6e3800557fa7efb562a69f80eea9b516c0ad2e54b9a013c92118bf91daaf2bdd2a9ced309626fab13fe9b979f0c768ac22bba63c7fa8aa3443004d50359d844 WHIRLPOOL 90e8c7bf065609e6a85d247c15b1022ea51bb94b000841c30a69d99c96082a08125fca58cf5b216990c6b746f52af5cedebbafc5b9450a91c0d32cdc21951952
 DIST mitaka-cinder-policy.json 4959 SHA256 5a9cd9d5d4cf80a9271fd7a5146d6d5415d10f8d699a8499a39a3cde29f50bd6 SHA512 b36daa51ab7719e1a56ca760e7ec62a98fb3a88ffed96196852023abf4ffe483200c9dcb934e3c7910fc6988f9c2bb9bb914121d0d649dc3b01466f467a82fe2 WHIRLPOOL f288b6dba2593fa6deb8ad94862948899ec10f71e4751f108ec1fbfff814c3206b5c541aaac0bb7edd2fb5311639a1cd3a44586855912cb2e0e675d5ad78161c
diff --git a/sys-cluster/cinder/cinder-8.0.0.ebuild b/sys-cluster/cinder/cinder-8.0.0.ebuild
new file mode 100644
index 000000000000..2836a339940e
--- /dev/null
+++ b/sys-cluster/cinder/cinder-8.0.0.ebuild
@@ -0,0 +1,175 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_4 )
+
+inherit distutils-r1 eutils linux-info user
+
+DESCRIPTION="Cinder is the OpenStack Block storage service, a spin out of nova-volumes"
+HOMEPAGE="https://launchpad.net/cinder"
+SRC_URI="https://tarballs.openstack.org/${PN}/${P}.tar.gz
+	https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/mitaka/cinder.conf.sample -> mitaka-cinder.conf.sample
+	https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/mitaka/api-paste.ini -> mitaka-cinder-api-paste.ini
+	https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/mitaka/policy.json -> mitaka-cinder-policy.json
+	https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/mitaka/volume.filters -> mitaka-cinder-volume.filters"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+api +scheduler +volume iscsi lvm mysql +memcached postgres sqlite test"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+CDEPEND=">=dev-python/pbr-1.6[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	app-admin/sudo"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	dev-python/enum34[$(python_gen_usedep 'python2_7')]
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/keystonemiddleware-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-reports-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-1.16.0[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/python-barbicanclient-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/python-glanceclient-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-1.6.0[${PYTHON_USEDEP}]
+	!~dev-python/python-keystoneclient-1.8.0[${PYTHON_USEDEP}]
+	!~dev-python/python-keystoneclient-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-2.29.0[${PYTHON_USEDEP}]
+	!~dev-python/python-novaclient-2.33.0[${PYTHON_USEDEP}]
+	>=dev-python/python-swiftclient-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+	!~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	>=dev-python/taskflow-1.26.0[${PYTHON_USEDEP}]
+	>=dev-python/rtslib-fb-2.1.41[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		dev-python/mysql-python
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		dev-python/psycopg:2
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	>=dev-python/sqlalchemy-migrate-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.5.0[${PYTHON_USEDEP}]
+	~dev-python/suds-0.6[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.2.3-r1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-vmware-1.16.0[${PYTHON_USEDEP}]
+	>=dev-python/os-brick-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/os-win-0.2.3[${PYTHON_USEDEP}]
+	>=dev-python/tooz-1.28.0[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.4.2[${PYTHON_USEDEP}]
+	iscsi? (
+		sys-block/tgt
+		sys-block/open-iscsi
+	)
+	lvm? ( sys-fs/lvm2 )
+	memcached? ( net-misc/memcached )
+	app-emulation/qemu
+	sys-fs/sysfsutils"
+# qemu is needed for image conversion
+
+#PATCHES=(
+#)
+
+pkg_setup() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES="ISCSI_TCP"
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be built as module (builtin doesn't work)"
+		done
+	fi
+	enewgroup cinder
+	enewuser cinder -1 -1 /var/lib/cinder cinder
+}
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Let's track progress of this # https://bugs.launchpad.net/swift/+bug/1249727
+	nosetests -I test_wsgi.py cinder/tests/ || die "tests failed under python2.7"
+}
+
+python_install() {
+	distutils-r1_python_install
+	keepdir /etc/cinder
+	dodir /etc/cinder/rootwrap.d
+
+	for svc in api scheduler volume; do
+		newinitd "${FILESDIR}/cinder.initd" cinder-${svc}
+	done
+
+	insinto /etc/cinder
+	insopts -m0640 -o cinder -g cinder
+	doins "etc/cinder/api-httpd.conf"
+	doins "etc/cinder/logging_sample.conf"
+	doins "etc/cinder/rootwrap.conf"
+	newins "${DISTDIR}/mitaka-cinder-api-paste.ini" "api-paste.ini"
+	newins "${DISTDIR}/mitaka-cinder-policy.json" "policy.json"
+	newins "${DISTDIR}/mitaka-cinder.conf.sample" "cidner.conf.sample"
+	insinto /etc/cinder/rootwrap.d
+	newins "${DISTDIR}/mitaka-cinder-volume.filters" "volume.filters"
+
+	dodir /var/log/cinder
+	fowners cinder:cinder /var/log/cinder
+
+	#add sudoers definitions for user nova
+	insinto /etc/sudoers.d/
+	insopts -m 0440 -o root -g root
+	newins "${FILESDIR}/cinder.sudoersd" cinder
+}
+
+pkg_postinst() {
+	if use iscsi ; then
+		elog "Cinder needs tgtd to be installed and running to work with iscsi"
+		elog "it also needs 'include /var/lib/cinder/volumes/*' in /etc/tgt/targets.conf"
+	fi
+}