sys-cluster/cinder: 10.0.1 bup

Package-Manager: Portage-2.3.3, Repoman-2.3.1

2 files changed, 195 insertions, 0 deletions

diff --git a/sys-cluster/cinder/Manifest b/sys-cluster/cinder/Manifest
index 8d5b12d73cf8..478373f24332 100644
--- a/sys-cluster/cinder/Manifest
+++ b/sys-cluster/cinder/Manifest
@@ -1,4 +1,5 @@
 DIST cinder-10.0.0.tar.gz 4610356 SHA256 3047812d07cebbcb5559cdc3a1d827fa62be35c2297cd3c1359b52dc8349ea04 SHA512 b55e95b84b09287b5786b6a07a6d2699ae0ca55dbd0dc9089a4e14fa039e2576b6eaefccf05e0eff0f9d36ebbe2aac0a4dd0de6122ae104cc3335d00174e82ed WHIRLPOOL 8f7bdc067a4b7e3d7f62a5a1c0d3bd15b8d461fb25d0d07efdfcab7d09a5cd2b34dded54334ddd14e515e8ceb9c2531353284773eef1d4f2acaa96eff95789a6
+DIST cinder-10.0.1.tar.gz 4615220 SHA256 160fdc3e173e3fc8d8ac3b440efd3a59dc86de92a11f92c0aeae266ca63273df SHA512 c23f5ac466643729a635449ceb1efd73e670d4548de2256aa5297b1c1e389f94ac7362e9fdb8dd599b10a0faea62a562813d18dce8f7ca9fe5fd225a80e8ae58 WHIRLPOOL 1fd34980626183af6cc810b2304a807be38bee69d18099db3fd8c44257ed3d438ef09c6f62be74c50635e65cfd6a39e99567858b3c63bf6c25660817394a9dae
 DIST cinder-8.1.1.tar.gz 3875392 SHA256 57de9d1410e9e5a0568499e38414241167e4b2b1742aac309844da80efd127e2 SHA512 4dfa5a11b11b684761519b33d1b45f4d65152df96fc9303e92724f88a01bea031e0dd7aaa229d5876641fa4a5089fcd197e52cf01652a89f6027435b038f3560 WHIRLPOOL 9815230914da588529f3f3916ddfdb25025a531015fd78fce635a6e55b6051f2a26f2e4710cd980daceb905f41caaceb274f84c34353bbc363a36e12a88c8245
 DIST cinder-9.1.2.tar.gz 4202510 SHA256 03415a9fc0280263d9094e385ce08af1ad3daed2227baa8c258744e400cd97c2 SHA512 bc5b8d58128df458f80120d061da5b2e097c8ce4daa6ee9b7c5e1062a1074861e9e33f547f4a5c2005316d1ad9f8f3b2f3e2d5825492ba6fa0becf8fdf3a41ee WHIRLPOOL dc8a74fdd513fdeb0cf321498a504ef9803480ae254a2f7e65853f27867699a54311fcb0ad2c248d06fccd5d914eda20335fce9f6efd983e5d03bd59f6851a40
 DIST cinder-9.1.3.tar.gz 4205643 SHA256 73e9df6dd47544cb49bf333d038182aa5814f3c39daf03a7ef465b2868e9a217 SHA512 6e0af3f205b6ee64240fc2d68e8c54f2e97ef11f560fc9f42a67c41c83eabe757ba56df1f3059500120b8780b59708212e36eae45e8c7c46a0fbb4df87f5a99f WHIRLPOOL 1778329077a6bc5c941a69eadabf7e73df00714e663caa44bf69d23af7da7c1315e72fcca5b3e11ca0f72b4833dc6462c9a38001a812dcea8c0d0a727d918991
diff --git a/sys-cluster/cinder/cinder-10.0.1.ebuild b/sys-cluster/cinder/cinder-10.0.1.ebuild
new file mode 100644
index 000000000000..7c997e7c2a22
--- /dev/null
+++ b/sys-cluster/cinder/cinder-10.0.1.ebuild
@@ -0,0 +1,194 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_4 )
+
+inherit distutils-r1 eutils linux-info user
+
+DESCRIPTION="Cinder is the OpenStack Block storage service, a spin out of nova-volumes"
+HOMEPAGE="https://launchpad.net/cinder"
+SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/ocata/cinder.conf.sample -> ocata-cinder.conf.sample
+https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/ocata/policy.json -> ocata-cinder-policy.json
+https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/ocata/volume.filters -> ocata-cinder-volume.filters
+https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+api +scheduler +volume infiniband iscsi lvm mysql +memcached postgres rdma sqlite +tcp test +tgt"
+REQUIRED_USE="|| ( mysql postgres sqlite ) iscsi? ( tgt ) infiniband? ( rdma )"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]
+	<dev-python/pbr-2.0.0[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	app-admin/sudo"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	dev-python/enum34[$(python_gen_usedep 'python2_7')]
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	!~dev-python/lxml-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-3.14.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.15.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.11.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-5.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-privsep-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-reports-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.0[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-barbicanclient-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-glanceclient-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-6.0.0[${PYTHON_USEDEP}]
+	!~dev-python/python-novaclient-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-swiftclient-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.10.0[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.12.2[${PYTHON_USEDEP}]
+	>=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+	!~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	!~dev-python/routes-2.3[${PYTHON_USEDEP}]
+	>=dev-python/taskflow-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/rtslib-fb-2.1.43[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.60[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.61[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		>=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+		!~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		>=dev-python/psycopg-2.5.0
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	>=dev-python/sqlalchemy-migrate-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.17.1[${PYTHON_USEDEP}]
+	~dev-python/suds-0.6[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-vmware-2.17.0[${PYTHON_USEDEP}]
+	>=dev-python/os-brick-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/os-win-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tooz-1.47.0[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.4.2[${PYTHON_USEDEP}]
+	>=dev-python/castellan-0.4.0[${PYTHON_USEDEP}]
+	iscsi? (
+		tgt? ( sys-block/tgt )
+		sys-block/open-iscsi
+	)
+	lvm? ( sys-fs/lvm2 )
+	memcached? ( net-misc/memcached )
+	app-emulation/qemu
+	sys-fs/sysfsutils"
+# qemu is needed for image conversion
+
+#PATCHES=(
+#)
+
+pkg_pretend() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES=""
+	if use tcp; then
+		CONFIG_CHECK_MODULES+="SCSI_ISCSI_ATTRS ISCSI_TCP "
+	fi
+	if use rdma; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_ISER "
+	fi
+	if use infiniband; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_IPOIB INFINIBAND_USER_MAD INFINIBAND_USER_ACCESS"
+	fi
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled"
+		done
+	fi
+}
+
+pkg_setup() {
+	enewgroup cinder
+	enewuser cinder -1 -1 /var/lib/cinder cinder
+}
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Let's track progress of this # https://bugs.launchpad.net/swift/+bug/1249727
+	nosetests -I test_wsgi.py cinder/tests/ || die "tests failed under python2.7"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	keepdir /etc/cinder
+	dodir /etc/cinder/rootwrap.d
+
+	for svc in api scheduler volume; do
+		newinitd "${FILESDIR}/cinder.initd" cinder-${svc}
+	done
+
+	insinto /etc/cinder
+	insopts -m0640 -o cinder -g cinder
+	doins "etc/cinder/api-httpd.conf"
+	doins "etc/cinder/logging_sample.conf"
+	doins "etc/cinder/rootwrap.conf"
+	doins "etc/cinder/api-paste.ini"
+	newins "${DISTDIR}/ocata-cinder-policy.json" "policy.json"
+	newins "${DISTDIR}/ocata-cinder.conf.sample" "cinder.conf.sample"
+	insinto /etc/cinder/rootwrap.d
+	newins "${DISTDIR}/ocata-cinder-volume.filters" "volume.filters"
+
+	dodir /var/log/cinder
+	fowners cinder:cinder /var/log/cinder
+
+	#add sudoers definitions for user nova
+	insinto /etc/sudoers.d/
+	insopts -m 0440 -o root -g root
+	newins "${FILESDIR}/cinder.sudoersd" cinder
+}
+
+pkg_postinst() {
+	if use iscsi ; then
+		elog "Cinder needs tgtd to be installed and running to work with iscsi"
+		elog "it also needs 'include /var/lib/cinder/volumes/*' in /etc/tgt/targets.conf"
+	fi
+}