sys-devel/prelink: add systemd timer

Signed-off-by: Andrew Udvare <audvare@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/16047
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 69 insertions, 0 deletions

diff --git a/sys-devel/prelink/prelink-20151030-r1.ebuild b/sys-devel/prelink/prelink-20151030-r1.ebuild
new file mode 100644
index 000000000000..596f57b3912d
--- /dev/null
+++ b/sys-devel/prelink/prelink-20151030-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2002-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+MY_PN="${PN}-cross"
+MY_P="${MY_PN}-${PV}"
+
+inherit autotools flag-o-matic systemd
+
+DESCRIPTION="Modifies ELFs to avoid runtime symbol resolutions resulting in faster load times"
+HOMEPAGE="https://git.yoctoproject.org/cgit/cgit.cgi/prelink-cross/ https://people.redhat.com/jakub/prelink"
+SRC_URI="https://git.yoctoproject.org/cgit/cgit.cgi/${MY_PN}/snapshot/${MY_P}.tar.bz2
+	doc? ( https://people.redhat.com/jakub/prelink/prelink.pdf )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="doc selinux"
+
+RDEPEND=">=dev-libs/elfutils-0.100
+	selinux? ( sys-libs/libselinux )
+	!dev-libs/libelf"
+DEPEND="${RDEPEND}
+	sys-libs/binutils-libs"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20130503-prelink-conf.patch
+	"${FILESDIR}"/${PN}-20130503-libiberty-md5.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e '/^CC=/s: : -Wl,--disable-new-dtags :' testsuite/functions.sh #100147
+
+	has_version 'dev-libs/elfutils[threads]' && append-ldflags -pthread
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable selinux)
+}
+
+src_install() {
+	default
+
+	use doc && dodoc "${DISTDIR}"/prelink.pdf
+
+	insinto /etc
+	doins doc/prelink.conf
+
+	exeinto /etc/cron.daily
+	newexe "${FILESDIR}"/prelink.cron prelink
+	newconfd "${FILESDIR}"/prelink.confd prelink
+	systemd_dounit "${FILESDIR}"/prelink.{service,timer}
+}
+
+pkg_postinst() {
+	if [ -z "${REPLACING_VERSIONS}" ] ; then
+		elog "You may wish to read the Gentoo Linux Prelink Guide, which can be"
+		elog "found online at:"
+		elog "    https://wiki.gentoo.org/wiki/Prelink"
+		elog "Please edit /etc/conf.d/prelink to enable and configure prelink"
+	fi
+}