sys-fs/android-file-transfer-linux: Bump to version 4.0

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

3 files changed, 82 insertions, 0 deletions

diff --git a/sys-fs/android-file-transfer-linux/Manifest b/sys-fs/android-file-transfer-linux/Manifest
index a8876426eaa4..e53fefdb0db9 100644
--- a/sys-fs/android-file-transfer-linux/Manifest
+++ b/sys-fs/android-file-transfer-linux/Manifest
@@ -1,2 +1,3 @@
 DIST android-file-transfer-linux-3.8.tar.gz 780911 BLAKE2B 07b4e7670125b1ff382e7c6b1e36427fe0c1fd9665106d73144de5ca68692ae390496985fe83550ec90a64a83fa45b27e4e6d6738e4590ca8c5078a4814ac141 SHA512 b311b76658b57d16cd11c8f5bf03630adc6e0f1939d985a75e7effab584c93dbb82e65fb4cf84a9ef453c901c7f7d3100b96737de20577235fae6fd156a03da1
 DIST android-file-transfer-linux-3.9.tar.gz 781268 BLAKE2B 63032a39b39cf31b8d051c0069c0357f0b6ed5bd9e592ee5ce1f5e95438ff27571ec7d58789eb865a1896097c3cebf0ec30a89526b62c93694d71ca29e95d415 SHA512 7468ff19d2b4ae0f768eea70ec45246da11c4e541d07a9548d057c080adbbc905f76dcdff18c4c8478cd19aee6992d02beaf8b4275d7302997652e25351ab5c8
+DIST android-file-transfer-linux-4.0.tar.gz 820094 BLAKE2B 1cb7150647e09a9f3dbe30cdf8ff01e122c9bab5a450c9bbe58fc8e3c8b48de0e2b6d571c8e7fa71de25fff28b803ef60aed7f8a77129919bdf9f482fff975ee SHA512 31083d3f7adb06ba0b5e79738825f5a10f3f4ce7e5b24498f7255224c11a9d978b814749c4b5fd60a5ec2b4c7d06bc85ad4b0cfb6cbcf6b3ff3f7e331c6c03f1
diff --git a/sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.0.ebuild b/sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.0.ebuild
new file mode 100644
index 000000000000..3ef7155a7e2c
--- /dev/null
+++ b/sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit cmake python-single-r1 xdg
+
+DESCRIPTION="Android File Transfer for Linux"
+HOMEPAGE="https://github.com/whoozle/android-file-transfer-linux"
+
+if [[ "${PV}" = *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/whoozle/android-file-transfer-linux.git"
+else
+	SRC_URI="https://github.com/whoozle/android-file-transfer-linux/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+IUSE="fuse libressl python qt5 taglib zune"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	sys-apps/file
+	sys-libs/readline:0=
+	fuse? ( sys-fs/fuse:0 )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pybind11[${PYTHON_USEDEP}]
+		')
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+	)
+	taglib? ( media-libs/taglib )
+	zune? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	qt5? ( dev-qt/linguist-tools:5 )
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+# required to override src_prepare from xdg eclass
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FUSE="$(usex fuse)"
+		-DBUILD_MTPZ="$(usex zune)"
+		-DBUILD_PYTHON="$(usex python)"
+		-DBUILD_QT_UI="$(usex qt5)"
+		-DBUILD_SHARED_LIB="ON"
+		-DBUILD_TAGLIB="$(usex taglib)"
+		# Upstream recommends to keep this off as libusb is broken
+		-DUSB_BACKEND_LIBUSB="OFF"
+		$(usex qt5 '-DDESIRED_QT_VERSION=5' '')
+	)
+	cmake_src_configure
+}
diff --git a/sys-fs/android-file-transfer-linux/metadata.xml b/sys-fs/android-file-transfer-linux/metadata.xml
index 9746ecb92773..d01c43a440a2 100644
--- a/sys-fs/android-file-transfer-linux/metadata.xml
+++ b/sys-fs/android-file-transfer-linux/metadata.xml
@@ -10,5 +10,6 @@
   </upstream>
   <use>
     <flag name="fuse">Add FUSE mount helper</flag>
+    <flag name="zune">Enable support for Microsoft Zune</flag>
   </use>
 </pkgmetadata>